feat: 🚀 init

Author: KANAjetzt

root/mods-unpacked/GodotModding-UserProfile/assets/fonts/CascadiaCode.ttf

@@ -0,0 +1,6 @@
+[gd_resource type="DynamicFont" load_steps=2 format=2]
+
+[ext_resource path="res://mods-unpacked/KANA-UserProfile/assets/fonts/CascadiaCode.ttf" type="DynamicFontData" id=1]
+
+[resource]
+font_data = ExtResource( 1 )

root/mods-unpacked/GodotModding-UserProfile/assets/fonts/Heading.tres

@@ -0,0 +1,8 @@
+[gd_resource type="DynamicFont" load_steps=2 format=2]
+
+[ext_resource path="res://mods-unpacked/KANA-UserProfile/assets/fonts/CascadiaCode.ttf" type="DynamicFontData" id=1]
+
+[resource]
+size = 14
+outline_color = Color( 0.847059, 0.847059, 0.847059, 1 )
+font_data = ExtResource( 1 )

root/mods-unpacked/GodotModding-UserProfile/assets/fonts/text.tres

@@ -0,0 +1,91 @@
+[gd_resource type="Shader" format=2]
+
+[resource]
+code = "// https://godotshaders.com/shader/simple-blur-mixed-with-a-color/
+// https://gist.github.com/rohanrhu/11ffd387e1cc228d15bcea56fad4f593
+
+shader_type canvas_item;
+
+uniform float radius: hint_range(0., 1.) = 1;
+uniform bool animate = false;
+uniform float square_scale: hint_range(0., 1.) = 0.1;
+uniform float blur_amount : hint_range(-2.0, 10.0);
+uniform float mix_amount : hint_range(0.0, 1.0);
+uniform vec4 color_over : hint_color;
+
+void fragment() {
+    float sc = square_scale + square_scale/2.;
+    float r = square_scale + (1. - radius) * (square_scale/2.);
+    
+    float scax = 1. - square_scale;
+    
+    float dx;
+    float dy;
+    float d;
+    float a;
+    
+	vec4 blurred = textureLod(SCREEN_TEXTURE, SCREEN_UV, blur_amount);
+	vec4 fin = mix(blurred, color_over, mix_amount);
+	COLOR = fin;
+    
+    if (UV.x < square_scale && UV.y > scax) {
+        dx = square_scale - UV.x;
+        dy = scax - UV.y;
+        d = sqrt(pow(dx, 2.) + pow(dy, 2.));
+        a = asin(d);
+        
+        if (a > r) {
+            if (!animate) {
+                COLOR.a = 0.;
+            } else if (a > sc * sin(3.14 * fract(TIME))) {
+                COLOR.a = 0.;
+            }
+        }
+    }
+    
+    if (UV.x < square_scale && UV.y < square_scale) {
+        dx = square_scale - UV.x;
+        dy = square_scale - UV.y;
+        d = sqrt(pow(dx, 2.) + pow(dy, 2.));
+        a = asin(d);
+        
+        if (a > r) {
+            if (!animate) {
+                COLOR.a = 0.;
+            } else if (a > sc * sin(3.14 * fract(TIME))) {
+                COLOR.a = 0.;
+            }
+        }
+    }
+    
+    if (UV.x > scax && UV.y < square_scale) {
+        dx = scax - UV.x;
+        dy = square_scale - UV.y;
+        d = sqrt(pow(dx, 2.) + pow(dy, 2.));
+        a = asin(d);
+        
+        if (a > r) {
+            if (!animate) {
+                COLOR.a = 0.;
+            } else if (a > sc * sin(3.14 * fract(TIME))) {
+                COLOR.a = 0.;
+            }
+        }
+    }
+
+    if (UV.x > scax && UV.y > scax) {
+        dx = scax - UV.x;
+        dy = scax - UV.y;
+        d = sqrt(pow(dx, 2.) + pow(dy, 2.));
+        a = asin(d);
+        
+        if (a > r) {
+            if (!animate) {
+                COLOR.a = 0.;
+            } else if (a > sc * sin(3.14 * fract(TIME))) {
+                COLOR.a = 0.;
+            }
+        }
+    }
+}
+"

root/mods-unpacked/GodotModding-UserProfile/assets/shader/blur.tres

@@ -0,0 +1,48 @@
+extends MarginContainer
+
+
+signal mod_is_active_changed(mod_id, is_active)
+
+export(PackedScene) var mod_list_mod
+
+var section_name := "" setget _set_section_name
+
+onready var user_profile_name := $"%SectionName"
+onready var mod_list = $"%ModList"
+
+
+func _set_section_name(new_name: String) -> void:
+	section_name = new_name
+	user_profile_name.text = new_name
+
+
+func generate_mod_list(user_profile: ModLoaderUserProfile.Profile) -> void:
+	for mod_id in user_profile.mod_list.keys():
+		var new_mod_list_mod: HBoxContainer = mod_list_mod.instance()
+
+		new_mod_list_mod.connect("is_active_toggled", self, "_on_mod_is_active_toggled")
+		mod_list.add_child(new_mod_list_mod)
+		new_mod_list_mod.mod_id = mod_id
+		new_mod_list_mod.is_active = user_profile.mod_list[mod_id]
+
+		if ModLoaderStore.mod_data.has(mod_id):
+			var mod: ModData = ModLoaderStore.mod_data[mod_id]
+
+			# Check if mod is locked
+			if mod.is_locked:
+				# Disable the checkbox if it is
+				new_mod_list_mod.is_disabled = true
+				new_mod_list_mod.set_mandatory_color()
+
+			# Check if the mod is loadable
+			if not mod.is_loadable:
+				new_mod_list_mod.set_error_color()
+
+
+func clear_mod_list() -> void:
+	for child in mod_list.get_children():
+		mod_list.remove_child(child)
+		child.free()
+
+func _on_mod_is_active_toggled(mod_id: String, is_active: bool) -> void:
+	emit_signal("mod_is_active_changed", mod_id, is_active)

root/mods-unpacked/GodotModding-UserProfile/content/ModList.gd

@@ -0,0 +1,34 @@
+[gd_scene load_steps=4 format=2]
+
+[ext_resource path="res://mods-unpacked/KANA-UserProfile/content/ModList.gd" type="Script" id=1]
+[ext_resource path="res://mods-unpacked/KANA-UserProfile/content/ModListMod.tscn" type="PackedScene" id=2]
+[ext_resource path="res://mods-unpacked/KANA-UserProfile/assets/fonts/Heading.tres" type="DynamicFont" id=3]
+
+[node name="ModList" type="MarginContainer"]
+margin_left = 20.0
+margin_top = 20.0
+margin_right = 1900.0
+margin_bottom = 1060.0
+custom_constants/margin_top = 10
+custom_constants/margin_bottom = 10
+script = ExtResource( 1 )
+mod_list_mod = ExtResource( 2 )
+
+[node name="VBoxContainer" type="VBoxContainer" parent="."]
+margin_top = 10.0
+margin_right = 1880.0
+margin_bottom = 1030.0
+
+[node name="SectionName" type="Label" parent="VBoxContainer"]
+unique_name_in_owner = true
+margin_right = 1880.0
+margin_bottom = 19.0
+custom_fonts/font = ExtResource( 3 )
+text = "Active Mods"
+
+[node name="ModList" type="VBoxContainer" parent="VBoxContainer"]
+unique_name_in_owner = true
+margin_top = 23.0
+margin_right = 1880.0
+margin_bottom = 23.0
+size_flags_horizontal = 3

root/mods-unpacked/GodotModding-UserProfile/content/ModList.tscn

@@ -0,0 +1,49 @@
+extends HBoxContainer
+
+
+signal is_active_toggled(mod_id, is_active)
+
+export(Color) var color_error = Color.indianred
+export(Color) var color_mandatory = Color.darkgray
+
+var mod_id := "" setget _set_mod_id
+var is_active: bool setget _set_is_active
+var is_disabled := false setget _set_is_disabled
+
+onready var mod_id_label = $"%ModID"
+onready var check_box = $"%CheckBox"
+
+
+func set_error_color() -> void:
+	_set_label_color(color_error)
+
+
+func set_mandatory_color() -> void:
+	_set_label_color(color_mandatory)
+
+
+func _set_label_color(color: Color) -> void:
+	mod_id_label.add_color_override("font_color", color)
+
+
+func _set_mod_id(new_mod_id: String) -> void:
+	mod_id = new_mod_id
+	mod_id_label.text = new_mod_id
+
+
+func _set_is_active(new_is_active: bool) -> void:
+	is_active = new_is_active
+	check_box.pressed = new_is_active
+
+
+func _set_is_disabled(new_is_disabled: bool) -> void:
+	is_disabled = is_disabled
+	check_box.disabled = new_is_disabled
+
+
+func _on_CheckBox_toggled(button_pressed):
+	is_active = button_pressed
+
+
+func _on_CheckBox_pressed():
+	emit_signal("is_active_toggled", mod_id, is_active)

root/mods-unpacked/GodotModding-UserProfile/content/ModListMod.gd

@@ -0,0 +1,30 @@
+[gd_scene load_steps=3 format=2]
+
+[ext_resource path="res://mods-unpacked/KANA-UserProfile/content/ModListMod.gd" type="Script" id=1]
+[ext_resource path="res://mods-unpacked/KANA-UserProfile/assets/fonts/text.tres" type="DynamicFont" id=2]
+
+[node name="ModListMod" type="HBoxContainer"]
+margin_right = 1880.0
+size_flags_horizontal = 3
+script = ExtResource( 1 )
+color_mandatory = Color( 0.521569, 0.521569, 0.521569, 1 )
+
+[node name="ModID" type="Label" parent="."]
+unique_name_in_owner = true
+margin_top = 3.0
+margin_right = 938.0
+margin_bottom = 20.0
+size_flags_horizontal = 3
+custom_colors/font_color = Color( 0.741176, 0.741176, 0.741176, 1 )
+custom_fonts/font = ExtResource( 2 )
+text = "%MODNAME%"
+
+[node name="CheckBox" type="CheckBox" parent="."]
+unique_name_in_owner = true
+margin_left = 942.0
+margin_right = 1880.0
+margin_bottom = 24.0
+size_flags_horizontal = 3
+
+[connection signal="pressed" from="CheckBox" to="." method="_on_CheckBox_pressed"]
+[connection signal="toggled" from="CheckBox" to="." method="_on_CheckBox_toggled"]

root/mods-unpacked/GodotModding-UserProfile/content/ModListMod.tscn

@@ -0,0 +1,116 @@
+extends WindowDialog
+
+
+export(PackedScene) var user_profile_section: PackedScene
+export(String) var text_restart := "A game restart is required to apply the settings"
+export(String) var text_profile_create_error := "There was an error creating the profile - check logs"
+export(String) var text_profile_select_error := "There was an error selecting the profile - check logs"
+export(String) var text_profile_delete_error := "There was an error deleting the profile - check logs"
+export(String) var text_mod_enable_error := "There was an error enabling the mod - check logs"
+export(String) var text_mod_disable_error := "There was an error disabling the mod - check logs"
+export(String) var text_current_profile := " (Current Profile)"
+
+onready var user_profile_sections := $"%UserProfileSections"
+onready var profile_select = $"%ProfileSelect"
+onready var popup_new_profile = $"%PopupNewProfile"
+onready var input_profile_name = $"%InputProfileName"
+onready var button_profile_name_submit = $"%ButtonProfileNameSubmit"
+onready var button_new_profile = $"%ButtonNewProfile"
+onready var mod_list = $"%ModList"
+onready var info_text = $"%InfoText"
+
+
+func _ready() -> void:
+	_populate_profile_select()
+	_generate_user_profile_section()
+
+
+func _input(event) -> void:
+	if event is InputEventKey:
+		if event.pressed and event.scancode == KEY_U:
+			popup_centered() if not visible else hide()
+
+
+func _update_ui() -> void:
+	# Update the profile select list
+	_populate_profile_select()
+
+	# Update the Setting list
+	_generate_user_profile_section()
+
+func _populate_profile_select() -> void:
+	var index_current_profile: int
+
+	profile_select.clear()
+
+	for user_profile in ModLoaderUserProfile.get_all_as_array():
+		var is_current_profile := true if ModLoaderStore.current_user_profile == user_profile.name else false
+		profile_select.add_item(user_profile.name + text_current_profile if is_current_profile else user_profile.name)
+
+		# Get the item index of the current profile
+		if is_current_profile:
+			index_current_profile = profile_select.get_item_count() - 1
+
+	# Select current profile
+	profile_select.select(index_current_profile)
+
+
+func _generate_user_profile_section() -> void:
+	mod_list.clear_mod_list()
+	mod_list.generate_mod_list(ModLoaderUserProfile.get_current())
+
+
+func _on_ButtonNewProfile_pressed() -> void:
+	popup_new_profile.popup_centered()
+
+
+func _on_ButtonDeleteProfile_pressed():
+	var profile_to_delete := ModLoaderStore.current_user_profile
+	# Switch to default profile
+	if not ModLoaderUserProfile.set_profile("default"):
+		info_text.text = text_profile_select_error
+		return
+	# Delete the profile
+	if not ModLoaderUserProfile.delete_profile(profile_to_delete):
+		info_text.text = text_profile_delete_error
+		return
+
+	_update_ui()
+
+
+func _on_ButtonProfileNameSubmit_pressed() -> void:
+	# Create new User Profile
+	if not ModLoaderUserProfile.create_profile(input_profile_name.text):
+		# If there was an error creating the profile
+		# Add error message to the info text label
+		info_text.text = text_profile_create_error
+		# And return early
+		return
+
+	_update_ui()
+
+	# Close popup
+	popup_new_profile.hide()
+
+
+func _mod_is_active_changed(mod_id: String, is_active: bool) -> void:
+	if is_active:
+		if not ModLoaderUserProfile.enable_mod(mod_id):
+			info_text.text = text_mod_enable_error
+			return
+	else:
+		if not ModLoaderUserProfile.disable_mod(mod_id):
+			info_text.text = text_mod_disable_error
+			return
+
+	info_text.text = text_restart
+
+
+func _on_ProfileSelect_item_selected(index: int) -> void:
+	if not ModLoaderUserProfile.set_profile(profile_select.get_item_text(index)):
+		info_text.text = text_profile_select_error
+		return
+
+	_update_ui()
+
+	info_text.text = text_restart