serialize into ModData and ModDetails for better type safety and convenience

Author: Qubus0

addons/mod_loader/mod_data.gd

@@ -0,0 +1,90 @@
+extends Resource
+class_name ModData
+
+# These 2 files are always required by mods.
+# mod_main.gd = The main init file for the mod
+# manifest.json = Meta data for the mod, including its dependancies
+const LOG_NAME := "ModLoader:ModData"
+
+enum required_mod_files {
+	MOD_MAIN,
+	MANIFEST,
+}
+
+var dir_name := "" # technically a duplicate with ModDetails
+var dir_path := ""
+var is_loadable := true
+var importance := 0
+var details: ModDetails
+var config := {} # updated in _load_mod_configs
+
+# debug
+var file_paths := []
+
+
+func _init(_dir_path: String) -> void:
+	dir_path = _dir_path
+
+
+# Load meta data from a mod's manifest.json file
+func load_details(modLoader = ModLoader) -> void:
+	if not has_required_files():
+		return
+
+	modLoader.mod_log("Loading mod_details (manifest.json) for -> %s" % dir_name, LOG_NAME)
+
+	# Load meta data file
+	var manifest_path = get_required_mod_file_path(required_mod_files.MANIFEST)
+	var manifest_dict = modLoader._get_json_as_dict(manifest_path) # todo get from utils
+
+	modLoader.dev_log("%s loaded manifest data -> %s" % [dir_name, manifest_dict], LOG_NAME)
+
+	var mod_details := ModDetails.new(manifest_dict)
+
+	if not mod_details:
+		is_loadable = false
+		return
+
+	details = mod_details
+
+
+func is_mod_dir_name_same_as_id() -> bool:
+	# Check that the mod ID is correct. This will fail if the mod's folder in
+	# "res://mods-unpacked" does not match its full ID, which is `namespace.name`
+	var manifest_id = details.get_mod_id()
+	if dir_name != manifest_id:
+		ModLoader.mod_log('ERROR - Mod directory name "%s" does not match the data in manifest.json. Expected "%s"' % [ dir_name, manifest_id ], LOG_NAME)
+		is_loadable = false
+		return false
+	return true
+
+
+func has_required_files() -> bool:
+	var file_check = File.new()
+
+	for required_file in required_mod_files:
+		var file_path = get_required_mod_file_path(required_mod_files[required_file])
+
+		if !file_check.file_exists(file_path):
+			ModLoader.mod_log("ERROR - %s is missing a required file: %s" % [dir_name, file_path], LOG_NAME)
+			is_loadable = false
+	return is_loadable
+
+
+func has_details() -> bool:
+	return not details == null
+
+
+func get_required_mod_file_path(required_file: int) -> String:
+	match required_file:
+		required_mod_files.MOD_MAIN:
+			return dir_path.plus_file("mod_main.gd")
+		required_mod_files.MANIFEST:
+			return dir_path.plus_file("manifest.json")
+	return ""
+
+
+#func _to_string() -> String:
+	# todo if we want it pretty printed
+
+

addons/mod_loader/mod_details.gd

@@ -0,0 +1,132 @@
+extends Resource
+class_name ModDetails
+
+var name := ""
+var namespace := ""
+var version_number := "v0.0.0"
+var description := ""
+var website_url := ""
+var dependencies := []				# Array[String]
+
+var authors := [] 					# Array[String]
+var compatible_game_version := [] 	# Array[String]
+var tags := [] 						# Array[String]
+var description_rich := ""
+var incompatibilities := [] 			# Array[String]
+var image: StreamTexture
+
+## Required keys in a mod's manifest.json file
+const REQUIRED_MANIFEST_KEYS_ROOT = [
+	"name",
+	"namespace",
+	"version_number",
+	"website_url",
+	"description",
+	"dependencies",
+	"extra",
+]
+
+## Required keys in manifest's `json.extra.godot`
+const REQUIRED_MANIFEST_KEYS_EXTRA = [
+	"authors",
+	"compatible_mod_loader_version",
+	"compatible_game_version",
+	"incompatibilities",
+	"config_defaults",
+]
+
+
+func _init(manifest: Dictionary) -> void:
+	if (not dict_has_fields(manifest, REQUIRED_MANIFEST_KEYS_ROOT) or
+		not dict_has_fields(manifest.extra, ["godot"]) or
+		not dict_has_fields(manifest.extra.godot, REQUIRED_MANIFEST_KEYS_EXTRA)):
+			return
+
+	name = manifest.name
+	namespace = manifest.namespace
+	version_number = manifest.version_number
+	if (not is_name_or_namespace_valid(name) or
+		not is_name_or_namespace_valid(namespace) or
+		not is_semver_valid(version_number)):
+			return
+
+
+	description = manifest.description
+	website_url = manifest.website_url
+	dependencies = manifest.dependencies
+
+	var 	godot_details: Dictionary = manifest.extra.godot
+	authors = _get_array_from_dict(godot_details, "authors")
+	incompatibilities = _get_array_from_dict(godot_details, "incompatibilities")
+	compatible_game_version = _get_array_from_dict(godot_details, "compatible_game_version")
+	description_rich = _get_string_from_dict(godot_details, "description_rich")
+	tags = _get_array_from_dict(godot_details, "tags")
+
+	# todo load file named icon.png when loading mods and use here
+#	image StreamTexture
+
+
+func get_mod_id() -> String:
+	return "%s-%s" % [namespace, name]
+
+
+func get_package_id() -> String:
+	return "%s-%s-%s" % [namespace, name, version_number]
+
+
+static func is_name_or_namespace_valid(name: String) -> bool:
+	var re := RegEx.new()
+	re.compile("^[a-zA-Z0-9_]*$") # alphanumeric and _
+
+	if re.search(name) == null:
+		printerr('Invalid name or namespace: "%s". You may only use letters, numbers and underscores.' % name)
+		return false
+
+	re.compile("^[a-zA-Z0-9_]{3,}$") # at least 3 long
+	if re.search(name) == null:
+		printerr('Invalid name or namespace: "%s". Must be longer than 3 characters.' % name)
+		return false
+
+	return true
+
+
+func _get_string_from_dict(dict: Dictionary, key: String) -> String:
+	if not dict.has(key):
+		return ""
+	return dict[key]
+
+
+func _get_array_from_dict(dict: Dictionary, key: String) -> Array:
+	if not dict.has(key):
+		return []
+	return dict[key]
+
+
+static func is_semver_valid(version_number: String) -> bool:
+	var re := RegEx.new()
+	re.compile("^[0-9]+\\.[0-9]+\\.[0-9]+$")
+
+	if re.search(version_number) == null:
+		printerr('Invalid semantic version: "%s". You may only use numbers and periods in this format {mayor}.{minor}.{patch}' % version_number)
+		return false
+
+	return true
+
+
+static func dict_has_fields(dict: Dictionary, required_fields: Array) -> bool:
+	var missing_fields := required_fields
+
+	for key in dict.keys():
+		if(required_fields.has(key)):
+			missing_fields.erase(key)
+
+	if missing_fields.size() > 0:
+		printerr("Mod data is missing required fields: " + str(missing_fields))
+		return false
+
+	return true
+
+
+#func _to_json()	-> String:
+#	return ""
+