Add Enum.sum/2

Author: sabiwara

lib/elixir/lib/enum.ex

@@ -3473,6 +3473,29 @@ defmodule Enum do
     reduce(enumerable, 0, &+/2)
   end
 
+  @doc """
+  Maps and sums the given enumerable in one pass.
+
+  Raises `ArithmeticError` if `fun` returns a non-numeric value.
+
+  ## Examples
+
+      iex> Enum.sum([%{count: 1}, %{count: 2}, %{count: 3}], fn x -> x.count end)
+      6
+
+      iex> Enum.sum(1..3, fn x -> x ** 2 end)
+      14
+
+      iex> Enum.sum([], fn x -> x.count end)
+      0
+
+  """
+  @doc since: "1.16.0"
+  @spec sum(t, (element -> number)) :: number
+  def sum(enumerable, fun) when is_function(fun, 1) do
+    reduce(enumerable, 0, fn x, acc -> acc + fun.(x) end)
+  end
+
   @doc """
   Returns the product of all elements.
 

lib/elixir/test/elixir/enum_test.exs

@@ -1321,6 +1321,24 @@ defmodule EnumTest do
     end
   end
 
+  test "sum/2" do
+    assert Enum.sum([], &hd/1) == 0
+    assert Enum.sum([[1]], &hd/1) == 1
+    assert Enum.sum([[1], [2], [3]], &hd/1) == 6
+    assert Enum.sum([[1.1], [2.2], [3.3]], &hd/1) == 6.6
+    assert Enum.sum([[-3], [-2], [-1], [0], [1], [2], [3]], &hd/1) == 0
+
+    assert Enum.sum(1..3, &(&1 ** 2)) == 14
+
+    assert_raise ArithmeticError, fn ->
+      Enum.sum([[{}]], &hd/1)
+    end
+
+    assert_raise ArithmeticError, fn ->
+      Enum.sum([[1], [{}]], &hd/1)
+    end
+  end
+
   test "product/1" do
     assert Enum.product([]) == 1
     assert Enum.product([1]) == 1