implement dbg for code blocks (#13619)

Author: dkuku

lib/elixir/lib/macro.ex

@@ -2599,7 +2599,18 @@ defmodule Macro do
     quote do
       unquote(acc_var) = []
       unquote(dbg_boolean_tree(ast, acc_var, result_var))
-      {:logic_op, Enum.reverse(unquote(acc_var))}
+      {:logic_op, Enum.reverse(unquote(acc_var)), unquote(result_var)}
+    end
+  end
+
+  defp dbg_ast_to_debuggable({:__block__, _meta, exprs} = ast, _env) when exprs != [] do
+    acc_var = unique_var(:acc, __MODULE__)
+    result_var = unique_var(:result, __MODULE__)
+
+    quote do
+      unquote(acc_var) = []
+      unquote(dbg_block(ast, acc_var, result_var))
+      {:block, Enum.reverse(unquote(acc_var)), unquote(result_var)}
     end
   end
 
@@ -2693,6 +2704,18 @@ defmodule Macro do
     end
   end
 
+  defp dbg_block({:__block__, meta, exprs}, acc_var, result_var) do
+    modified_exprs =
+      Enum.map(exprs, fn expr ->
+        quote do
+          unquote(result_var) = unquote(expr)
+          unquote(acc_var) = [{unquote(escape(expr)), unquote(result_var)} | unquote(acc_var)]
+        end
+      end)
+
+    {:__block__, meta, modified_exprs}
+  end
+
   # Made public to be called from Macro.dbg/3, so that we generate as little code
   # as possible and call out into a function as soon as we can.
   @doc false
@@ -2730,15 +2753,27 @@ defmodule Macro do
     {[first_formatted | rest_formatted], result}
   end
 
-  defp dbg_format_ast_to_debug({:logic_op, components}, options) do
-    {_ast, final_value} = List.last(components)
-
+  defp dbg_format_ast_to_debug({:logic_op, components, value}, options) do
     formatted =
       Enum.map(components, fn {ast, value} ->
         [dbg_format_ast(to_string_with_colors(ast, options)), " ", inspect(value, options), ?\n]
       end)
 
-    {formatted, final_value}
+    {formatted, value}
+  end
+
+  defp dbg_format_ast_to_debug({:block, components, value}, options) do
+    formatted =
+      [
+        dbg_maybe_underline("Code block", options),
+        ":\n(\n",
+        Enum.map(components, fn {ast, value} ->
+          ["  ", dbg_format_ast_with_value(ast, value, options)]
+        end),
+        ")\n"
+      ]
+
+    {formatted, value}
   end
 
   defp dbg_format_ast_to_debug({:case, ast, expr_value, clause_index, value}, options) do

lib/elixir/test/elixir/macro_test.exs

@@ -453,6 +453,30 @@ defmodule MacroTest do
              """
     end
 
+    test "with block of code" do
+      {result, formatted} =
+        dbg_format(
+          (
+            a = 1
+            b = a + 2
+            a + b
+          )
+        )
+
+      assert result == 4
+
+      assert formatted =~ "macro_test.exs"
+
+      assert formatted =~ """
+             Code block:
+             (
+               a = 1 #=> 1
+               b = a + 2 #=> 3
+               a + b #=> 4
+             )
+             """
+    end
+
     test "with case" do
       list = [1, 2, 3]