feat: Add Ninja support (#299)

Author: jcs090218

.gitmodules

@@ -564,3 +564,9 @@
 	update = none
 	ignore = dirty
 	branch = main
+[submodule "repos/ninja"]
+	path = repos/ninja
+	url = https://github.com/alemuller/tree-sitter-ninja
+	update = none
+	ignore = dirty
+	branch = main

CHANGELOG.md

@@ -1,6 +1,7 @@
 # Changelog
 
 ## Unreleased
+- Add `Ninja` support
 
 ## 0.12.88 - 2023-12-21
 

queries/ninja/highlights.scm

@@ -0,0 +1,98 @@
+[
+  "default"
+  "pool"
+  "rule"
+  "build"
+] @keyword
+
+[
+  "include"
+  "subninja"
+] @include
+
+[
+  ":"
+] @punctuation.delimiter
+
+[
+  "="
+  "|"
+  "||"
+  "|@"
+] @operator
+
+[
+  "$"
+  "{"
+  "}"
+] @punctuation.special
+
+;;
+;; Names
+;; =====
+(pool      name: (identifier) @type)
+(rule      name: (identifier) @function)
+(let       name: (identifier) @constant)
+(expansion       (identifier) @constant)
+(build     rule: (identifier) @function)
+
+;;
+;; Paths and Text
+;; ==============
+(path) @string.special
+(text) @string
+
+;;
+;; Builtins
+;; ========
+(pool  name: (identifier) @type.builtin
+                (#any-of? @type.builtin "console"))
+(build rule: (identifier) @function.builtin
+                (#any-of? @function.builtin "phony" "dyndep"))
+
+;; Top level bindings
+;; ------------------
+(manifest
+  (let name: ((identifier) @constant.builtin
+                 (#any-of? @constant.builtin "builddir"
+                                             "ninja_required_version"))))
+
+;; Rules bindings
+;; -----------------
+(rule
+  (body
+    (let name: (identifier)  @constant.builtin
+               (#not-any-of? @constant.builtin "command"
+                                               "depfile"
+                                               "deps"
+                                               "msvc_deps_prefix"
+                                               "description"
+                                               "dyndep"
+                                               "generator"
+                                               "in"
+                                               "in_newline"
+                                               "out"
+                                               "restat"
+                                               "rspfile"
+                                               "rspfile_content"
+                                               "pool"))))
+
+;;
+;; Expansion
+;; ---------
+(expansion
+  (identifier) @constant.macro
+     (#any-of? @constant.macro "in" "out"))
+
+;;
+;; Escape sequences
+;; ================
+(quote) @string.escape
+
+;;
+;; Others
+;; ======
+[
+ (split)
+ (comment)
+] @comment

repos/ninja

@@ -177,6 +177,7 @@ See `tree-sitter-langs-repos'."
                 (matlab-mode            . matlab)
                 (mermaid-mode           . mermaid)
                 (meson-mode             . meson)
+                (ninja-mode             . ninja)
                 (noir-mode              . noir)
                 (ocaml-mode             . ocaml)
                 (org-mode               . org)