initial pure nix build

Author: sevanspowell

build.sbt

@@ -1,5 +1,10 @@
 enablePlugins(JDKPackagerPlugin, JavaAppPackaging, SolidityPlugin)
 
+import scala.sys.process.Process
+
+// Necessary for the nix build, please do not remove.
+val nixBuild = sys.props.isDefinedAt("nix")
+
 val commonSettings = Seq(
   name := "mantis",
   version := "3.0",
@@ -15,7 +20,7 @@ val dep = {
   val akkaHttpVersion = "10.1.1"
   val circeVersion = "0.9.3"
   val rocksDb = "5.9.2"
-  
+
   Seq(
     "com.typesafe.akka" %% "akka-actor" % akkaVersion,
     "com.typesafe.akka" %% "akka-slf4j" % akkaVersion,
@@ -73,7 +78,8 @@ val Snappy = config("snappy") extend Test
 
 val Rpc = config("rpcTest") extend Test
 
-val root = project.in(file("."))
+val root = {
+  val x = project.in(file("."))
     .configs(Integration, Benchmark, Evm, Ets, Snappy, Rpc)
     .settings(commonSettings: _*)
     .settings(
@@ -88,6 +94,12 @@ val root = project.in(file("."))
     .settings(inConfig(Snappy)(Defaults.testSettings) : _*)
     .settings(inConfig(Rpc)(Defaults.testSettings) : _*)
 
+  if (!nixBuild)
+    x
+  else
+    x.settings(PB.runProtoc in Compile := (args => Process("protoc", args) !))
+}
+
 scalacOptions := Seq(
   "-unchecked",
   "-deprecation",

default.nix

@@ -0,0 +1,3 @@
+{ system ? builtins.currentSystem, src ? ./.
+, pkgs ? (import ./nix { inherit system src; }).pkgs }:
+pkgs.mantis

manual-repo.nix

@@ -0,0 +1,26 @@
+# this file must still be generated manually.  
+{
+  "repos" = {
+    "nix-public" = "";
+    "nix-typesafe-ivy-releases" = "[organisation]/[module]/(scala_[scalaVersion]/)(sbt_[sbtVersion]/)[revision]/[type]s/[artifact](-[classifier]).[ext]";
+  };
+  "artifacts" = {
+    # dependencies so sbt can build the sbt-compiler-interface (http://www.scala-sbt.org/0.13/docs/Compiler-Interface.html)
+    "nix-public/org/scala-lang/jline/2.10.6/jline-2.10.6.pom" = {
+      url = "https://repo1.maven.org/maven2/org/scala-lang/jline/2.10.6/jline-2.10.6.pom";
+      sha256 = "16mg4b2c1m6gcq901wy6f6jpy8spw2yh909gi826xykq89ja94dg";
+    };
+    "nix-public/org/scala-lang/jline/2.10.6/jline-2.10.6.jar" = {
+      url = "https://repo1.maven.org/maven2/org/scala-lang/jline/2.10.6/jline-2.10.6.jar";
+      sha256 = "1cfk6whncx2g87grwdfmz6f76bn807saqik91iwcfv099b1jngw1";
+    };
+    "nix-public/org/fusesource/jansi/jansi/1.4/jansi-1.4.pom" = {
+      url = "https://repo1.maven.org/maven2/org/fusesource/jansi/jansi/1.4/jansi-1.4.pom";
+      sha256 = "0rgprkbg4ljarf0x79snk2h1b0974glhl2fw1bxkxbw8k3ifda1s";
+    };
+    "nix-public/org/fusesource/jansi/jansi/1.4/jansi-1.4.jar" = {
+      url = "https://repo1.maven.org/maven2/org/fusesource/jansi/jansi/1.4/jansi-1.4.jar";
+      sha256 = "183ms545msn02fl0181rwbcifc8qy82rz4l6dglnhv9la8a1bnc2";
+    };
+  };
+}

nix/default.nix

@@ -0,0 +1,25 @@
+{ system ? builtins.currentSystem, sources ? import ./sources.nix, src ? ../. }:
+
+let
+  overlay = final: prev: {
+    inherit sources;
+    inherit (import sources.gitignore { inherit (prev) lib; }) gitignoreSource;
+
+    sbtix = prev.callPackage ../sbtix.nix {
+      jdk = prev.openjdk8_headless;
+      jre = prev.openjdk8_headless.jre;
+    };
+
+    mantisPkgs = final.callPackage ./pkgs/mantis {
+      inherit (prev.openjdk8_headless) jre;
+      inherit src;
+    };
+
+    inherit (final.mantisPkgs) mantis;
+
+    inherit (final.mantisPkgs) mantis-unwrapped;
+  };
+in import sources.nixpkgs {
+  inherit system;
+  overlays = [ overlay ];
+}

nix/pkgs/default.nix

@@ -0,0 +1,13 @@
+{ pkgs, lib, newScope, sources, src, impure ? false }:
+
+lib.makeScope newScope (self:
+  with self;
+  let callPackages = lib.callPackagesWith (pkgs // self);
+  in {
+    inherit sources src impure;
+    jdk = prev.openjdk8_headless;
+    libsonic = callPackage ./libsonic.nix { };
+    libsonic-jnr = callPackage sources.libsonic-jnr { };
+    netty-native-epoll = callPackage ./netty-native-epoll { };
+    progpow-cpu-scala = callPackage sources.progpow-cpu-scala { };
+  })

nix/pkgs/libsonic.nix

@@ -0,0 +1,13 @@
+{ rustPlatform, sources }:
+
+rustPlatform.buildRustPackage {
+  name        = "libsonic";
+  src         = sources.libsonic;
+  doCheck     = false;
+  cargoSha256 = "sha256:0zhbzr3amwmdqbrmj355ryl5fsmmw85h8ksaggcqwp66zmv57aq4";
+
+  preConfigure = ''
+    substituteInPlace libsonic/Cargo.toml  \
+      --replace 'crate-type = ["staticlib"]' 'crate-type = ["cdylib"]'
+  '';
+}

nix/pkgs/mantis/default.nix

@@ -0,0 +1,26 @@
+{ src, lib, gitignoreSource, callPackage, jre }: rec {
+
+  mkSrc = src:
+    let
+      isGit = builtins.pathExists (src + "/.git");
+      repo = builtins.fetchGit { url = src; submodules = true; };
+      dirty = repo.revCount == 0;
+      filterSrc = src:
+        lib.cleanSourceWith {
+          inherit src;
+          filter = path: _: !lib.hasSuffix "nix" path;
+        };
+    in if isGit then
+      if dirty then filterSrc (gitignoreSource src) else repo
+    else
+      src;
+
+  mantis-source = src;
+
+  mantis-unwrapped = callPackage ./unwrapped.nix { src = mantis-source; };
+
+  mantis = callPackage ./wrapped.nix {
+    mantis = mantis-unwrapped;
+    inherit jre;
+  };
+}

nix/pkgs/mantis/unwrapped.nix

@@ -0,0 +1,66 @@
+# this file originates from SBTix
+{ src, stdenv, writeShellScriptBin, bash, protobuf, sbtix
+, solc, jdk, impure ? false }:
+
+let
+  inherit (stdenv.lib) optionalString makeLibraryPath;
+  inherit (stdenv) cc isDarwin;
+
+  LD_LIBRARY_PATH = makeLibraryPath [ cc.cc.lib ];
+
+  unlessDarwin = optionalString (!stdenv.isDarwin);
+
+  # sbt-protoc puts the scala plugin in /tmp/protobridge<some-random-number>.
+  # it is in fact a shell script with a standard `#!/usr/bin/env sh` shebang
+  # that makes the Nix sandbox ANGRY and breaks all the things in a cryptic,
+  # hairpull-inducing way. So we gotta sed it out. Not the prettiest thing
+  # but it works.
+  protoc-wrapper = writeShellScriptBin "protoc" ''
+    set -e
+
+    for f in "$@"; do
+      echo ''${f##*=}
+    done | grep protocbridge | xargs sed -i "1s|.*|#!${bash}/bin/bash|"
+
+    exec ${protobuf}/bin/protoc "$@"
+  '';
+
+in sbtix.buildSbtProject {
+  inherit src;
+
+  name = "mantis";
+  sbtOptions = "-Dnix=true";
+  buildInputs = [ protoc-wrapper ];
+  sbtixBuildInputs = [];
+
+  repo = [
+    (import ../../../repo.nix)
+    (import ../../../project/repo.nix)
+    (import ../../../manual-repo.nix)
+  ];
+
+  buildPhase = ''
+    set -x
+    pwd && sbt compile
+  '';
+
+  installPhase = ''
+    sbt stage
+    mkdir -p $out/
+    cp wallet-backend/target/universal/stage/* $out/ -r
+    cp node/target/universal/stage/* $out/ -r
+    mkdir -p $out/share/mantis
+    mv $out/{LICENSE,RELEASE,mantis_config.txt} $_
+
+    ${optionalString (!impure) ''
+      for p in $(find $out/bin/* -executable); do
+        wrapProgram "$p" \
+        --prefix PATH : ${jdk}/bin ${
+          unlessDarwin "--prefix LD_LIBRARY_PATH : ${LD_LIBRARY_PATH}"
+        }
+      done
+    ''}
+  '';
+
+  dontPatchShebangs = impure;
+}

nix/pkgs/mantis/wrapped.nix

@@ -0,0 +1,33 @@
+{ lib, stdenv, mantis, makeWrapper, jre, gawk }:
+let
+  inherit (stdenv.lib) optionalString makeLibraryPath;
+  inherit (stdenv) cc isDarwin;
+  LD_LIBRARY_PATH = makeLibraryPath [ cc.cc.lib ];
+  PATH = lib.makeBinPath [ jre gawk ];
+in stdenv.mkDerivation {
+  pname = "mantis";
+  version = let
+    buildSbt = builtins.readFile ../../../build.sbt;
+    captures = builtins.match ''.*version := "([^"]+)".*'' buildSbt;
+  in builtins.elemAt captures 0;
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  src = mantis;
+
+  buildPhase = ":";
+
+  installPhase = ''
+    cp -r $src $out
+    chmod -R u+rw $out
+
+    for p in $(find $out/bin/* -executable); do
+      wrapProgram "$p" \
+        --prefix PATH : ${PATH} \
+        ${
+          optionalString (!isDarwin)
+          "--prefix LD_LIBRARY_PATH : ${LD_LIBRARY_PATH}"
+        }
+    done
+  '';
+}

nix/pkgs/netty-native-epoll/default.nix

@@ -0,0 +1,62 @@
+# How to bump the netty-transport-epoll version:
+# 1. Update the netty niv pin.
+# 2. nix-shell, then cd in this dir, then run mvnix-update to update
+#    the `mavenix.lock` lock file.
+
+{ sources, lib, autoconf, automake, git, gnumake, gnutar, jdk, libaio, libtool
+, makeWrapper, maven, mavenix, unzip }:
+mavenix.buildMaven {
+  src = sources.netty;
+  doCheck = false;
+  infoFile = ./mavenix.lock;
+
+  MAVEN_OPTS = "-DskipTests";
+
+  # Adding some build dependencies.
+  # Netty-transport-epoll requires both the autotool suite and the JDK
+  buildInputs = [
+    git
+    makeWrapper
+    autoconf
+    automake
+    libtool
+    gnumake
+    gnutar
+    libaio
+    jdk
+    maven
+  ];
+  # Attributes are passed to the underlying `stdenv.mkDerivation`, so build
+  #   hooks can be set here also.
+  #
+  postInstall = ''
+    libName="libnetty_transport_native_epoll_x86_64.so"
+    mkdir -p $out/lib
+    ${unzip}/bin/unzip $out/share/java/netty-transport-native-epoll-*-linux-x86_64.jar META-INF/native/libnetty_transport_native_epoll_x86_64.so -d .
+    cp META-INF/native/libnetty_transport_native_epoll_x86_64.so $out/lib/$libName
+    chmod 777 $out/lib/$libName
+  '';
+
+  meta.platforms = lib.platforms.linux;
+
+  # Add extra maven dependencies which might not have been picked up
+  #   automatically
+  #
+  #deps = [
+  #  { path = "org/group-id/artifactId/version/file.jar"; sha1 = "0123456789abcdef"; }
+  #  { path = "org/group-id/artifactId/version/file.pom"; sha1 = "123456789abcdef0"; }
+  #];
+
+  # Add dependencies on other mavenix derivations
+  #
+  #drvs = [ (import ../other/mavenix/derivation {}) ];
+
+  # Override which maven package to build with
+  #
+  #maven = maven.overrideAttrs (_: { jdk = pkgs.oraclejdk10; });
+
+  # Override remote repository URLs and settings.xml
+  #
+  #remotes = { central = "https://repo.maven.apache.org/maven2"; };
+  #settings = ./settings.xml;
+}