meson: handle uriparser dependency if not installed in host system

Quite a few more lines added to handle disabling a cmake define
Unfortunately Meson doesn't offer an easy way to do
dependency('uriparser', default_options: {'URIPARSER_BUILD_DOCS': false})
where the second argument is automatically given to cmake

Author: AdelKS

meson.build

@@ -219,6 +219,7 @@ install_headers(
 )
 
 compiler = meson.get_compiler('cpp')
+cmake   = import('cmake')
 
 deps = [
   dependency('boost'),
@@ -246,13 +247,28 @@ deps = [
   dependency('pugixml'),
   dependency('rtaudio'),
   dependency('sndfile'),
-  dependency('uriparser'),
   dependency('utf8cpp'),
   dependency('x11-xcb'),
   dependency('xcursor'),
   compiler.find_library('freeimage', has_headers: ['FreeImage.h']),
 ]
 
+# We need to treat this dependency independently 
+# because if it's not installed in the host system,
+# we will use the .wrap file in the subprojects file AND 
+# need to change a define in the cmake subproject
+uriparser_dep = dependency('uriparser', required: false)
+if not uriparser_dep.found()
+  # disable the "URIPARSER_BUILD_DOCS" define that is default enabled in the subproject
+  # which pulls Doxygen dependency uselessly
+  uripaser_opts = cmake.subproject_options()
+  uripaser_opts.add_cmake_defines({'URIPARSER_BUILD_DOCS': false})
+  uripaser_proj = cmake.subproject('uriparser', options: uripaser_opts)
+  uriparser_dep = uripaser_proj.dependency('uriparser')
+endif
+
+deps += [uriparser_dep]
+
 lib = library('openFrameworks',
   sources,
   include_directories: inc,

subprojects/uriparser.wrap

@@ -0,0 +1,8 @@
+[wrap-git]
+url = https://github.com/uriparser/uriparser.git
+revision = uriparser-0.9.8
+depth = 1
+method = cmake
+
+[provide]
+uriparser = uriparser_dep