meson: add libtess2 subproject wrap file and a meson override

Author: AdelKS

subprojects/libtess2.wrap

@@ -0,0 +1,13 @@
+[wrap-git]
+url = https://github.com/memononen/libtess2.git
+revision = v1.0.2
+depth = 1
+
+# Loads "overrides" (aka move files from that folder to the cloned one) from packagefiles/libtess2
+# this is to "meson-ize" the project
+# There are many meson-ized projects in here https://mesonbuild.com/Wrapdb-projects.html
+# more information on how to use them here https://mesonbuild.com/Wrap-dependency-system-manual.html
+patch_directory = libtess2
+
+[provide]
+dependency_names = libtess2_dep

subprojects/packagefiles/libtess2/meson.build

@@ -0,0 +1,43 @@
+project('libtess2', 'c',
+version : '0.12.0',
+default_options : [
+  'buildtype=release',
+  'optimization=3',
+  'default_library=static',
+  'prefer_static=true',
+  'b_ndebug=if-release',
+  'c_args=-pipe',
+  'cpp_args=-pipe',
+]
+)
+
+inc = include_directories(
+  'Include',
+  'Source'
+)
+
+install_headers('Include/tesselator.h')
+
+sources = files(
+  'Source/bucketalloc.c',
+  'Source/dict.c',
+  'Source/geom.c',
+  'Source/mesh.c',
+  'Source/priorityq.c',
+  'Source/sweep.c',
+  'Source/tess.c',
+)
+
+lib = library('tess2',
+  sources,
+  include_directories: inc,
+  install: true)
+
+libtess2_dep = declare_dependency(include_directories: 'Include', link_with: lib)
+
+# This is to make meson projects using this one as subproject find the dependency
+# automagically when doing "dependency('libtess2')"
+meson.override_dependency('libtess2', libtess2_dep)
+
+pkg = import('pkgconfig')
+pkg.generate(lib)