Большой рефакторинг библиотеки

Author: khorevaa

src/core/Классы/internal/Классы/ЗагрузчикПлагинов.os

@@ -0,0 +1,127 @@
+#Использовать opm 
+
+Перем ВнутреннийМенеджерУстановкиПакетов;
+Перем ИндексУстановленныхПлагинов;
+Перем Лог;
+Перем ДоступныйИнтерфейсПлагинов;
+Перем КаталогПлагинов;
+
+Процедура УстановитьКаталогПлагинов(Знач ПутьККаталогу) Экспорт
+	КаталогПлагинов = ПутьККаталогу;
+КонецПроцедуры
+
+Процедура ЗагрузитьПлагины() Экспорт
+	
+	ОбновитьИндексПлагинов();
+
+КонецПроцедуры
+
+Функция ИндексПлагинов() Экспорт
+	Возврат ИндексУстановленныхПлагинов;
+КонецФункции
+
+Процедура ОбновитьИндексПлагинов() 
+
+	Лог.Отладка("Обновление индекса плагина");
+	ИндексУстановленныхПлагинов = Новый Соответствие;
+
+	КаталогиПлагинов = НайтиФайлы(КаталогПлагинов, ПолучитьМаскуВсеФайлы(), Ложь); 
+
+	Для каждого Каталоги Из КаталогиПлагинов Цикл
+		
+		Если Не Каталоги.ЭтоКаталог() Тогда
+			Продолжить;
+		КонецЕсли;
+		
+		ЗагрузитьПлагин(Каталоги.ПолноеИмя);
+
+	КонецЦикла;
+
+	Лог.Отладка("В индекс плагинов добавлено <%1> плагинов", ИндексУстановленныхПлагинов.Количество());
+
+КонецПроцедуры
+
+Процедура ЗагрузитьПлагин(Знач Путь)
+
+	Лог.Отладка("Загружаю плагины из каталога <%1>", Путь);
+
+	ФайлМанифеста = Новый Файл(ОбъединитьПути(Путь, "lib.config"));
+	
+	Если ФайлМанифеста.Существует() Тогда
+		Лог.Отладка("Обрабатываем по манифесту");
+		ДобавитьКлассыПлагинов(ФайлМанифеста.ПолноеИмя, Путь);
+	Иначе
+		Лог.Отладка("Плагины из каталога <%1> не могут быть загружены - не найден файл <lib.config>", Путь);
+	КонецЕсли;
+
+КонецПроцедуры
+
+Процедура ДобавитьКлассыПлагинов(Знач Файл, Знач Путь)
+	
+	Чтение = Новый ЧтениеXML;
+	Чтение.ОткрытьФайл(Файл);
+	Чтение.ПерейтиКСодержимому();
+	
+	Если Чтение.ЛокальноеИмя <> "package-def" Тогда
+		Чтение.Закрыть();
+		Возврат;
+	КонецЕсли;
+	
+	Пока Чтение.Прочитать() Цикл
+		
+		Если Чтение.ТипУзла = ТипУзлаXML.Комментарий Тогда
+
+			Продолжить;
+
+		КонецЕсли;
+
+		Если Чтение.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда
+		
+			Если Чтение.ЛокальноеИмя = "class" Тогда
+				ФайлКласса = Новый Файл(ОбъединитьПути(Путь,Чтение.ЗначениеАтрибута("file")));
+				Если ФайлКласса.Существует() 
+					И ФайлКласса.ЭтоФайл() Тогда
+					Идентификатор = Чтение.ЗначениеАтрибута("name");
+					Если Не ПустаяСтрока(Идентификатор) Тогда
+						ДобавитьПлагинВИндекс(Идентификатор, ФайлКласса.ПолноеИмя);
+					КонецЕсли;
+				Иначе
+					ВызватьИсключение "Не найден файл " + ФайлКласса.ПолноеИмя + ", указанный в манифесте";
+				КонецЕсли;
+				
+				Чтение.Прочитать(); // в конец элемента
+
+			КонецЕсли;
+			
+		КонецЕсли;
+		
+	КонецЦикла;
+	
+	Чтение.Закрыть();
+	
+КонецПроцедуры
+
+Процедура ДобавитьПлагинВИндекс(Знач ИмяКлассаПлагина, Знач ИмяФайлаКласса)
+	
+	Лог.Отладка("Добавляю плагин <%1> в индекс плагинов", ИмяКлассаПлагина);
+
+	ПодключитьСценарий(ИмяФайлаКласса, ИмяКлассаПлагина);
+
+	Попытка
+		НовыйПлагин = Новый ПлагинСинхронизации(ИмяКлассаПлагина, ДоступныйИнтерфейсПлагинов);
+	Исключение
+		Лог.Отладка("Ошибка добавления плагина <%1> в индекс плагинов. Класс <%1> не найден", ИмяКлассаПлагина);
+		Возврат;
+	КонецПопытки;
+
+	ИндексУстановленныхПлагинов.Вставить(НовыйПлагин.Имя(), НовыйПлагин);
+
+КонецПроцедуры
+
+Процедура ПриСозданииОбъекта(Знач ВходящийКаталогПлагинов = Неопределено)
+	
+	КаталогПлагинов = ВходящийКаталогПлагинов;
+
+КонецПроцедуры
+
+Лог = Логирование.ПолучитьЛог("oscript.app.gitsync.plugins.loader");

src/core/Классы/internal/Классы/ИнтерфейсПлагинов.os

@@ -0,0 +1,94 @@
+#Использовать reflector
+
+Перем ОбъектИнтерфейс;
+
+Функция Интерфейс() Экспорт
+	Возврат ОбъектИнтерфейс;
+КонецФункции
+
+Функция Реализует(ОбъектПроверки) Экспорт
+
+	Рефлектор = Новый РефлекторОбъекта(ОбъектПроверки);
+	Возврат Рефлектор.РеализуетИнтерфейс(ОбъектИнтерфейс);
+
+КонецФункции
+
+Функция ПолучитьДоступныйИнтерфейсПлагинов()
+
+	ДоступныйИнтерфейсПлагинов = Новый ИнтерфейсОбъекта();
+	
+	// Вызывается в процедуре АктивизироватьПлагины
+	ДоступныйИнтерфейсПлагинов.П("ПриАктивизации", 1); //
+	ДоступныйИнтерфейсПлагинов.П("ПриПолученииПараметров", 2); //
+
+	// Подписки на регистрацию команд приложения
+	ДоступныйИнтерфейсПлагинов.П("ПослеРегистрацииКомандПриложения", 1); //
+	ДоступныйИнтерфейсПлагинов.П("ПриРегистрацииКомандыПриложения", 3); //
+	ДоступныйИнтерфейсПлагинов.П("ПриВыполненииКоманды", 2); //
+	ДоступныйИнтерфейсПлагинов.П("ПередВыполнениемКоманды", 3); //
+	ДоступныйИнтерфейсПлагинов.П("ПослеВыполненияКоманды", 3); //
+
+	// Подписки на начало и окончания выполнения
+	ДоступныйИнтерфейсПлагинов.П("ПередНачаломВыполнения", 4); //
+	ДоступныйИнтерфейсПлагинов.П("ПослеОкончанияВыполнения", 4);
+
+	// Подписки на получение таблицы версий
+	ДоступныйИнтерфейсПлагинов.П("ПриПолученииТаблицыВерсий", 3);
+	ДоступныйИнтерфейсПлагинов.П("ПослеПолученияТаблицыВерсий", 2);
+
+	// Подписки на получение таблицы пользователей
+	ДоступныйИнтерфейсПлагинов.П("ПриПолученииТаблицыПользователей", 3);
+	ДоступныйИнтерфейсПлагинов.П("ПослеПолученияТаблицыПользователей", 2);
+
+	// Подписки на обработки строки версии
+	ДоступныйИнтерфейсПлагинов.П("ПередНачаломЦиклаОбработкиВерсий", 4);
+	ДоступныйИнтерфейсПлагинов.П("ПередОбработкойВерсииХранилища", 2);
+	ДоступныйИнтерфейсПлагинов.П("ПриОбработкеВерсииХранилища", 2);
+	ДоступныйИнтерфейсПлагинов.П("ПослеОбработкиВерсииХранилища", 3);
+
+	// Подписки на выполнение коммита
+	ДоступныйИнтерфейсПлагинов.П("ПередКоммитом", 4);
+	ДоступныйИнтерфейсПлагинов.П("ПриКоммите", 7);
+	ДоступныйИнтерфейсПлагинов.П("ПослеКоммита", 2);
+
+	// Подписки на начало и окончания выгрузки версии конфигурации
+	ДоступныйИнтерфейсПлагинов.П("ПередНачаломВыгрузкиВерсииХранилищаКонфигурации", 5); //
+	ДоступныйИнтерфейсПлагинов.П("ПослеОкончанияВыгрузкиВерсииХранилищаКонфигурации", 5);
+
+	// Подписки на загрузку версии конфигурации из хранилища
+	ДоступныйИнтерфейсПлагинов.П("ПередЗагрузкойВерсииХранилищаКонфигурации", 5); //
+	ДоступныйИнтерфейсПлагинов.П("ПриЗагрузкеВерсииХранилищаВКонфигурацию", 5);
+	ДоступныйИнтерфейсПлагинов.П("ПослеЗагрузкиВерсииХранилищаВКонфигурацию", 4); //
+
+	// Подписки на выгрузку конфигурации в исходники
+	ДоступныйИнтерфейсПлагинов.П("ПередВыгрузкойКонфигурациюВИсходники", 6); //
+	ДоступныйИнтерфейсПлагинов.П("ПриВыгрузкеКонфигурациюВИсходники", 4);
+	ДоступныйИнтерфейсПлагинов.П("ПослеВыгрузкиКонфигурациюВИсходники", 3); //
+
+	// Подписки на очистку каталога рабочей версии
+	ДоступныйИнтерфейсПлагинов.П("ПередОчисткойКаталогаРабочейКопии", 6); //
+	ДоступныйИнтерфейсПлагинов.П("ПриОчисткеКаталогаРабочейКопии", 3);
+	ДоступныйИнтерфейсПлагинов.П("ПослеОчисткиКаталогаРабочейКопии", 2); //
+
+	// Подписки на перемещение в каталог рабочей копии
+	ДоступныйИнтерфейсПлагинов.П("ПередПеремещениемВКаталогРабочейКопии", 6); //
+	ДоступныйИнтерфейсПлагинов.П("ПриПеремещенииВКаталогРабочейКопии", 5);
+	ДоступныйИнтерфейсПлагинов.П("ПослеПеремещенияВКаталогРабочейКопии", 4); //
+
+	// Подписка на распаковку файлов form.bin
+	ДоступныйИнтерфейсПлагинов.П("ПриРаспаковкеКонтейнераМетаданных", 3);
+	ДоступныйИнтерфейсПлагинов.П("ПослеРаспаковкиКонтейнераМетаданных", 2); //
+
+
+	// Работа с выгрузкой в исходники
+	ДоступныйИнтерфейсПлагинов.П("ПередВыполнениемВыгрузки", 6);
+	ДоступныйИнтерфейсПлагинов.П("ПриВыполненииВыгрузки", 7);
+	ДоступныйИнтерфейсПлагинов.П("ПослеВыполненияВыгрузки", 6);
+	
+	Возврат ДоступныйИнтерфейсПлагинов;
+
+КонецФункции
+
+Процедура ПриСозданииОбъекта()
+	ОбъектИнтерфейс = ПолучитьДоступныйИнтерфейсПлагинов();
+КонецПроцедуры