Helpers to create random tensor.

Summary: #8366

Reviewed By: kirklandsign

Differential Revision: D74020936

Author: shoumikhin

extension/apple/ExecuTorch/Exported/ExecuTorchTensor.h

@@ -902,4 +902,82 @@ __attribute__((deprecated("This API is experimental.")))
 
 @end
 
+#pragma mark - Random Category
+
+@interface ExecuTorchTensor (Random)
+
+/**
+ * Creates a tensor with random values, with full specification of shape, strides, data type, and shape dynamism.
+ *
+ * @param shape An NSArray of NSNumber objects representing the desired shape.
+ * @param strides An NSArray of NSNumber objects representing the desired strides.
+ * @param dataType An ExecuTorchDataType value specifying the element type.
+ * @param shapeDynamism An ExecuTorchShapeDynamism value specifying whether the shape is static or dynamic.
+ * @return A new ExecuTorchTensor instance filled with random values.
+ */
++ (instancetype)randomTensorWithShape:(NSArray<NSNumber *> *)shape
+                              strides:(NSArray<NSNumber *> *)strides
+                             dataType:(ExecuTorchDataType)dataType
+                        shapeDynamism:(ExecuTorchShapeDynamism)shapeDynamism
+    NS_SWIFT_NAME(rand(shape:strides:dataType:shapeDynamism:));
+
+/**
+ * Creates a tensor with random values, with the specified shape and data type.
+ *
+ * @param shape An NSArray of NSNumber objects representing the desired shape.
+ * @param dataType An ExecuTorchDataType value specifying the element type.
+ * @param shapeDynamism An ExecuTorchShapeDynamism value specifying whether the shape is static or dynamic.
+ * @return A new ExecuTorchTensor instance filled with random values.
+ */
++ (instancetype)randomTensorWithShape:(NSArray<NSNumber *> *)shape
+                             dataType:(ExecuTorchDataType)dataType
+                        shapeDynamism:(ExecuTorchShapeDynamism)shapeDynamism
+    NS_SWIFT_NAME(rand(shape:dataType:shapeDynamism:));
+
+/**
+ * Creates a tensor with random values, with the specified shape (using dynamic bound shape) and data type.
+ *
+ * @param shape An NSArray of NSNumber objects representing the desired shape.
+ * @param dataType An ExecuTorchDataType value specifying the element type.
+ * @return A new ExecuTorchTensor instance filled with random values.
+ */
++ (instancetype)randomTensorWithShape:(NSArray<NSNumber *> *)shape
+                             dataType:(ExecuTorchDataType)dataType
+    NS_SWIFT_NAME(rand(shape:dataType:));
+
+/**
+ * Creates a tensor with random values similar to an existing tensor, with the specified data type and shape dynamism.
+ *
+ * @param tensor An existing ExecuTorchTensor instance whose shape and strides are used.
+ * @param dataType An ExecuTorchDataType value specifying the desired element type.
+ * @param shapeDynamism An ExecuTorchShapeDynamism value specifying whether the shape is static or dynamic.
+ * @return A new ExecuTorchTensor instance filled with random values.
+ */
++ (instancetype)randomTensorLikeTensor:(ExecuTorchTensor *)tensor
+                              dataType:(ExecuTorchDataType)dataType
+                         shapeDynamism:(ExecuTorchShapeDynamism)shapeDynamism
+    NS_SWIFT_NAME(rand(like:dataType:shapeDynamism:));
+
+/**
+ * Creates a tensor with random values similar to an existing tensor, with the specified data type.
+ *
+ * @param tensor An existing ExecuTorchTensor instance whose shape and strides are used.
+ * @param dataType An ExecuTorchDataType value specifying the desired element type.
+ * @return A new ExecuTorchTensor instance filled with random values.
+ */
++ (instancetype)randomTensorLikeTensor:(ExecuTorchTensor *)tensor
+                              dataType:(ExecuTorchDataType)dataType
+    NS_SWIFT_NAME(rand(like:dataType:));
+
+/**
+ * Creates a tensor with random values similar to an existing tensor.
+ *
+ * @param tensor An existing ExecuTorchTensor instance.
+ * @return A new ExecuTorchTensor instance filled with random values.
+ */
++ (instancetype)randomTensorLikeTensor:(ExecuTorchTensor *)tensor
+    NS_SWIFT_NAME(rand(like:));
+
+@end
+
 NS_ASSUME_NONNULL_END

extension/apple/ExecuTorch/Exported/ExecuTorchTensor.mm

@@ -775,3 +775,61 @@ + (instancetype)onesTensorLikeTensor:(ExecuTorchTensor *)tensor {
 }
 
 @end
+
+@implementation ExecuTorchTensor (Random)
+
++ (instancetype)randomTensorWithShape:(NSArray<NSNumber *> *)shape
+                              strides:(NSArray<NSNumber *> *)strides
+                             dataType:(ExecuTorchDataType)dataType
+                        shapeDynamism:(ExecuTorchShapeDynamism)shapeDynamism {
+  auto tensor = rand_strided(
+    utils::toVector<SizesType>(shape),
+    utils::toVector<StridesType>(strides),
+    static_cast<ScalarType>(dataType),
+    static_cast<TensorShapeDynamism>(shapeDynamism)
+  );
+  return [[self alloc] initWithNativeInstance:&tensor];
+}
+
++ (instancetype)randomTensorWithShape:(NSArray<NSNumber *> *)shape
+                             dataType:(ExecuTorchDataType)dataType
+                        shapeDynamism:(ExecuTorchShapeDynamism)shapeDynamism {
+  return [self randomTensorWithShape:shape
+                             strides:@[]
+                            dataType:dataType
+                       shapeDynamism:shapeDynamism];
+}
+
++ (instancetype)randomTensorWithShape:(NSArray<NSNumber *> *)shape
+                             dataType:(ExecuTorchDataType)dataType {
+  return [self randomTensorWithShape:shape
+                             strides:@[]
+                            dataType:dataType
+                       shapeDynamism:ExecuTorchShapeDynamismDynamicBound];
+}
+
++ (instancetype)randomTensorLikeTensor:(ExecuTorchTensor *)tensor
+                              dataType:(ExecuTorchDataType)dataType
+                         shapeDynamism:(ExecuTorchShapeDynamism)shapeDynamism {
+  return [self randomTensorWithShape:tensor.shape
+                             strides:tensor.strides
+                            dataType:dataType
+                       shapeDynamism:shapeDynamism];
+}
+
++ (instancetype)randomTensorLikeTensor:(ExecuTorchTensor *)tensor
+                              dataType:(ExecuTorchDataType)dataType {
+  return [self randomTensorWithShape:tensor.shape
+                             strides:tensor.strides
+                            dataType:dataType
+                       shapeDynamism:tensor.shapeDynamism];
+}
+
++ (instancetype)randomTensorLikeTensor:(ExecuTorchTensor *)tensor {
+  return [self randomTensorWithShape:tensor.shape
+                             strides:tensor.strides
+                            dataType:tensor.dataType
+                       shapeDynamism:tensor.shapeDynamism];
+}
+
+@end

extension/apple/ExecuTorch/__tests__/TensorTest.swift

@@ -618,4 +618,23 @@ class TensorTest: XCTestCase {
       }
     }
   }
+
+  func testRandom() {
+    let tensor = Tensor.rand(shape: [3, 3], dataType: .float)
+    XCTAssertEqual(tensor.shape, [3, 3])
+    XCTAssertEqual(tensor.count, 9)
+    tensor.bytes { pointer, count, dataType in
+      XCTAssertEqual(dataType, .float)
+      let buffer = UnsafeBufferPointer(start: pointer.assumingMemoryBound(to: Float.self), count: count)
+      let uniqueValues = Set(buffer.map { $0 })
+      XCTAssertTrue(uniqueValues.count > 1)
+    }
+  }
+
+  func testRandomLike() {
+    let other = Tensor.full(shape: [3, 3], scalar: 9, dataType: .int)
+    let tensor = Tensor.rand(like: other)
+    XCTAssertEqual(tensor.shape, other.shape)
+    XCTAssertEqual(tensor.count, other.count)
+  }
 }