Add ability to customize product name, version & banner [WIP]

To override the product name (defaulting to "RabbitMQ"):
* set the `$RABBITMQ_SERVER_PRODUCT_NAME` environment variable, or
* set the `rabbit` application `product_name` variable.

To override the product version:
* set the `$RABBITMQ_SERVER_PRODUCT_VERSION` environment variable, or
* set the `rabbit` application `product_version` variable.

To add content to the banner (both the copy logged and the one printed
to stdout), indicate the filename which contains it, à la `/etc/motd`
using:
* the `$RABBITMQ_SERVER_MOTD_FILE` environment variable, or
* the `rabbit` application `motd` variable.

Here is an example of the printed banner with name, version & motd
configured:

      ##  ##      WeatherMQ 1.2.3
      ##  ##
      ##########  Copyright (c) 2007-2020 Pivotal Software, Inc.
      ######  ##
      ##########  Licensed under the MPL 1.1. Website: https://rabbitmq.com

      This is an example of a RabbitMQ message of the day.

      The message is written in Paris, France.    \  /
      It is partly cloudy outside, with a       _ /"".-.
      temperature of 12°C. Wind is around         \_(   ).
      30-40 km/h, from south-west.                /(___(__)

      Doc guides: https://rabbitmq.com/documentation.html
      Support:    https://rabbitmq.com/contact.html
      Tutorials:  https://rabbitmq.com/getstarted.html
      Monitoring: https://rabbitmq.com/monitoring.html

      Logs: /tmp/rabbitmq-test-instances/rabbit/log/[email protected]
            /tmp/rabbitmq-test-instances/rabbit/log/rabbit@cassini_upgrade.log

      Config file(s): /tmp/rabbitmq-test-instances/test.config

      Starting broker... completed with 0 plugins.

New APIS are available to query those product informations and use them
in e.g. plugins such as the management API/UI:
* rabbit:product_info/0
* rabbit:product_name/0
* rabbit:product_version/0
* rabbit:product_motd/0

Author: dumbbell

src/rabbit.erl

@@ -30,6 +30,7 @@
 
 -export([start/2, stop/1, prep_stop/1]).
 -export([start_apps/1, start_apps/2, stop_apps/1]).
+-export([product_infos/0, product_name/0, product_version/0, product_motd/0]).
 -export([log_locations/0, config_files/0]). %% for testing and mgmt-agent
 -export([is_booted/1, is_booted/0, is_booting/1, is_booting/0]).
 
@@ -376,8 +377,9 @@ run_prelaunch_second_phase() ->
 start_it(StartType) ->
     case spawn_boot_marker() of
         {ok, Marker} ->
+            Product = product_name(),
             T0 = erlang:timestamp(),
-            rabbit_log:info("RabbitMQ is asked to start...", []),
+            rabbit_log:info("~s is asked to start...", [Product]),
             try
                 {ok, _} = application:ensure_all_started(rabbitmq_prelaunch,
                                                          StartType),
@@ -387,8 +389,8 @@ start_it(StartType) ->
 
                 T1 = erlang:timestamp(),
                 rabbit_log_prelaunch:debug(
-                  "Time to start RabbitMQ: ~p µs",
-                  [timer:now_diff(T1, T0)]),
+                  "Time to start ~s: ~p µs",
+                  [Product, timer:now_diff(T1, T0)]),
                 stop_boot_marker(Marker),
                 ok
             catch
@@ -436,10 +438,12 @@ stop() ->
         ok ->
             case rabbit_boot_state:get() of
                 ready ->
-                    rabbit_log:info("RabbitMQ is asked to stop..."),
+                    Product = product_name(),
+                    rabbit_log:info("~s is asked to stop...", [Product]),
                     do_stop(),
                     rabbit_log:info(
-                      "Successfully stopped RabbitMQ and its dependencies"),
+                      "Successfully stopped ~s and its dependencies",
+                      [Product]),
                     ok;
                 stopped ->
                     ok
@@ -463,7 +467,9 @@ stop_and_halt() ->
     try
         stop()
     catch Type:Reason ->
-        rabbit_log:error("Error trying to stop RabbitMQ: ~p:~p", [Type, Reason]),
+        rabbit_log:error(
+          "Error trying to stop ~s: ~p:~p",
+          [product_name(), Type, Reason]),
         error({Type, Reason})
     after
         %% Enclose all the logging in the try block.
@@ -519,9 +525,9 @@ stop_apps([]) ->
     ok;
 stop_apps(Apps) ->
     rabbit_log:info(
-        lists:flatten(["Stopping RabbitMQ applications and their dependencies in the following order:~n",
+        lists:flatten(["Stopping ~s applications and their dependencies in the following order:~n",
                        ["    ~p~n" || _ <- Apps]]),
-        lists:reverse(Apps)),
+        [product_name() | lists:reverse(Apps)]),
     ok = app_utils:stop_applications(
            Apps, handle_app_error(error_during_shutdown)),
     case lists:member(rabbit, Apps) of
@@ -664,7 +670,7 @@ maybe_print_boot_progress(true, IterationsLeft) ->
                {memory, any()}].
 
 status() ->
-    {ok, Version} = application:get_key(rabbit, vsn),
+    Version = product_version(),
     S1 = [{pid,                  list_to_integer(os:getpid())},
           %% The timeout value used is twice that of gen_server:call/2.
           {running_applications, rabbit_misc:which_applications()},
@@ -817,9 +823,10 @@ start(normal, []) ->
     try
         run_prelaunch_second_phase(),
 
-        rabbit_log:info("~n Starting RabbitMQ ~s on Erlang ~s~n ~s~n ~s~n",
-                        [rabbit_misc:version(), rabbit_misc:otp_release(),
+        rabbit_log:info("~n Starting ~s ~s on Erlang ~s~n ~s~n ~s~n",
+                        [product_name(), product_version(), rabbit_misc:otp_release(),
                          ?COPYRIGHT_MESSAGE, ?INFORMATION_MESSAGE]),
+        log_motd(),
         {ok, SupPid} = rabbit_sup:start_link(),
 
         %% Compatibility with older RabbitMQ versions + required by
@@ -905,7 +912,7 @@ do_run_postlaunch_phase() ->
                   end
           end, Plugins),
 
-        rabbit_log_prelaunch:debug("Marking RabbitMQ as running"),
+        rabbit_log_prelaunch:debug("Marking ~s as running", [product_name()]),
         rabbit_boot_state:set(ready),
 
         ok = rabbit_lager:broker_is_started(),
@@ -1059,8 +1066,8 @@ log_broker_started(Plugins) ->
         "~n  " ?BG32_START "          " ?C_END "  ~s").
 
 print_banner() ->
-    {ok, Product} = application:get_key(description),
-    {ok, Version} = application:get_key(vsn),
+    Product = product_name(),
+    Version = product_version(),
     LineListFormatter = fun (Placeholder, [_ | Tail] = LL) ->
                               LF = lists:flatten([Placeholder || _ <- lists:seq(1, length(Tail))]),
                               {LF, LL};
@@ -1083,8 +1090,21 @@ print_banner() ->
     %% padded list lines
     {LogFmt, LogLocations} = LineListFormatter("~n        ~ts", log_locations()),
     {CfgFmt, CfgLocations} = LineListFormatter("~n                  ~ts", config_locations()),
+    {MOTDFormat, MOTDArgs} = case product_motd() of
+                                 undefined ->
+                                     {"", []};
+                                 MOTD ->
+                                     Lines = string:split(MOTD, "\n", all),
+                                     Padded = [case Line of
+                                                   <<>> -> "\n";
+                                                   _    -> ["  ", Line, "\n"]
+                                               end
+                                               || Line <- Lines],
+                                     {"~n~ts", [Padded]}
+                             end,
     io:format(Logo ++
-              "~n"
+              "~n" ++
+              MOTDFormat ++
               "~n  Doc guides: https://rabbitmq.com/documentation.html"
               "~n  Support:    https://rabbitmq.com/contact.html"
               "~n  Tutorials:  https://rabbitmq.com/getstarted.html"
@@ -1094,9 +1114,24 @@ print_banner() ->
               "~n  Config file(s): ~ts" ++ CfgFmt ++ "~n"
               "~n  Starting broker...",
               [Product, Version, ?COPYRIGHT_MESSAGE, ?INFORMATION_MESSAGE] ++
+              MOTDArgs ++
               LogLocations ++
               CfgLocations).
 
+log_motd() ->
+    case product_motd() of
+        undefined ->
+            ok;
+        MOTD ->
+            Lines = string:split(MOTD, "\n", all),
+            Padded = [case Line of
+                          <<>> -> "\n";
+                          _    -> [" ", Line, "\n"]
+                      end
+                      || Line <- Lines],
+            rabbit_log:info("~n~ts", [string:trim(Padded, trailing, [$\r, $\n])])
+    end.
+
 log_banner() ->
     {FirstLog, OtherLogs} = case log_locations() of
         [Head | Tail] ->
@@ -1236,6 +1271,112 @@ validate_msg_store_io_batch_size_and_credit_disc_bound(CreditDiscBound,
             end
     end.
 
+-spec product_name() -> string().
+
+product_name() ->
+    #{name := ProductName} = product_infos(),
+    ProductName.
+
+-spec product_version() -> string().
+
+product_version() ->
+    #{version := ProductVersion} = product_infos(),
+    ProductVersion.
+
+-spec product_infos() -> #{name := string(),
+                           version := string()}.
+
+product_infos() ->
+    PTKey = {?MODULE, product},
+    try
+        %% The value is cached the first time to avoid calling the
+        %% application master many times just for that.
+        persistent_term:get(PTKey)
+    catch
+        error:badarg ->
+            %% FIXME: Move those variables to rabbit_env.
+            NameFromEnv = os:getenv("RABBITMQ_SERVER_PRODUCT_NAME"),
+            VersionFromEnv = os:getenv("RABBITMQ_SERVER_PRODUCT_VERSION"),
+            Info =
+            if
+                NameFromEnv =/= false andalso
+                VersionFromEnv =/= false ->
+                    #{name => NameFromEnv,
+                      version => VersionFromEnv};
+                true ->
+                    _ = application:load(rabbit),
+                    Name = case NameFromEnv of
+                               false ->
+                                   string_from_app_env(
+                                     product_name,
+                                     base_product_name());
+                               _ ->
+                                   NameFromEnv
+                           end,
+                    Version = case VersionFromEnv of
+                                  false ->
+                                      string_from_app_env(
+                                        product_version,
+                                        base_product_version());
+                                  _ ->
+                                      VersionFromEnv
+                              end,
+                    #{name => Name,
+                      version => Version}
+            end,
+            persistent_term:put(PTKey, Info),
+            Info
+    end.
+
+string_from_app_env(Key, Default) ->
+    case application:get_env(rabbit, Key) of
+        {ok, Val} ->
+            case io_lib:deep_char_list(Val) of
+                true ->
+                    case lists:flatten(Val) of
+                        ""     -> Default;
+                        String -> String
+                    end;
+                false ->
+                    Default
+            end;
+        undefined ->
+            Default
+    end.
+
+base_product_name() ->
+    %% This function assumes the `rabbit` application was loaded in
+    %% product_infos().
+    {ok, Product} = application:get_key(rabbit, description),
+    Product.
+
+base_product_version() ->
+    %% This function assumes the `rabbit` application was loaded in
+    %% product_infos().
+    rabbit_misc:version().
+
+product_motd() ->
+    File = case os:getenv("RABBITMQ_SERVER_MOTD_FILE") of
+               false ->
+                   _ = application:load(rabbit),
+                   string_from_app_env(motd, default_motd_file());
+               Val ->
+                   Val
+           end,
+    case File of
+        undefined ->
+            undefined;
+        _ ->
+            case file:read_file(File) of
+                {ok, MOTD} -> string:trim(MOTD, trailing, [$\r,$\n]);
+                {error, _} -> undefined
+            end
+    end.
+
+default_motd_file() ->
+    #{config_base_dir := Dir} = rabbit_env:get_context(),
+    filename:join(Dir, "motd").
+
 home_dir() ->
     case init:get_argument(home) of
         {ok, [[Home]]} -> Home;