ProtocolDevirtualizer Part 4: Test cases

Author: Raj Barik

test/SILOptimizer/protocol_devirtulize.sil

@@ -0,0 +1,54 @@
+// RUN: %target-sil-opt -wmo -assume-parsing-unqualified-ownership-sil -enable-sil-verify-all %s -protocol-devirtualizer -inline -sil-combine -generic-specializer -devirtualizer -late-inline -dead-arg-signature-opt -dce -sil-deadfuncelim | %FileCheck %s
+//
+import Builtin
+import Swift
+
+internal protocol SomeProtocol : AnyObject {
+  func increment() -> Int
+}
+
+internal class SomeClass : SomeProtocol {
+  init()
+  func increment() -> Int
+}
+
+// CHECK-LABEL: something
+// CHECK: bb0
+// CHECK: alloc_ref
+// CHECK-NOT: init_existential_ref
+// CHECK: function_ref @$S25something_to_devirtualizeTf5n_n4main9SomeClassC_Tg5
+sil @something : $@convention(thin) () -> Int {
+bb0:
+  %0 = alloc_ref $SomeClass
+  %1 = init_existential_ref %0 : $SomeClass : $SomeClass, $SomeProtocol
+  %2 = function_ref @something_to_devirtualize : $@convention(thin) (@guaranteed SomeProtocol) -> Int
+  %3 = apply %2(%1) : $@convention(thin) (@guaranteed SomeProtocol) -> Int
+  return %3 : $Int
+} 
+
+sil private [transparent] [thunk] @increment : $@convention(witness_method: SomeProtocol) (@guaranteed SomeClass) -> Int {
+bb0(%0 : $SomeClass):
+  %1 = integer_literal $Builtin.Int64, 10 
+  %2 = struct $Int (%1 : $Builtin.Int64) 
+  return %2 : $Int 
+} 
+
+// CHECK-LABEL: sil shared [noinline] @$S25something_to_devirtualizeTf5n_n4main9SomeClassC_Tg5 : $@convention(thin) (@guaranteed SomeClass) -> Int {
+// CHECK: bb0({{.*}}):
+// CHECK-NOT: open_existential_ref
+// CHECK-NOT: witness_method
+// CHECK-NOT: apply
+// CHECK: integer_literal
+// CHECK: struct
+// CHECK: return
+sil shared [noinline] @something_to_devirtualize : $@convention(thin) (@guaranteed SomeProtocol) -> Int {
+bb0(%0 : $SomeProtocol):
+  %2 = open_existential_ref %0 : $SomeProtocol to $@opened("D346AB00-F998-11E7-93AE-DCA9048B1C6D") SomeProtocol
+  %3 = witness_method $@opened("D346AB00-F998-11E7-93AE-DCA9048B1C6D") SomeProtocol, #SomeProtocol.increment!1 : <Self where Self : SomeProtocol> (Self) -> () -> Int, %2 : $@opened("D346AB00-F998-11E7-93AE-DCA9048B1C6D") SomeProtocol : $@convention(witness_method: SomeProtocol) <τ_0_0 where τ_0_0 : SomeProtocol> (@guaranteed τ_0_0) -> Int
+  %4 = apply %3<@opened("D346AB00-F998-11E7-93AE-DCA9048B1C6D") SomeProtocol>(%2) : $@convention(witness_method: SomeProtocol) <τ_0_0 where τ_0_0 : SomeProtocol> (@guaranteed τ_0_0) -> Int
+  return %4 : $Int
+}
+
+sil_witness_table hidden SomeClass: SomeProtocol module test {
+  method #SomeProtocol.increment!1: <Self where Self : SomeProtocol> (Self) -> () -> Int : @increment	
+}