[Exclusivity] access enforcement SIL tests.

Author: atrick

test/SILOptimizer/access_enforcement_selection.sil

@@ -0,0 +1,101 @@
+// RUN: %target-sil-opt -access-enforcement-selection -enforce-exclusivity=checked %s | %FileCheck %s
+
+import Builtin
+import Swift
+
+sil_stage raw
+
+// Test undef begin_access operands.
+// CHECK-LABEL: sil hidden @undefStack : $@convention(thin) (Builtin.Int64) -> Builtin.Int64 {
+// CHECK: bb0(%0 : $Builtin.Int64):
+// CHECK: unreachable
+// CHECK: bb1:
+// CHECK: [[WRITE:%.*]] = begin_access [modify] [static] undef : $*Builtin.Int64
+// CHECK: store %{{.*}} to [trivial] [[WRITE]] : $*Builtin.Int64
+// CHECK: end_access [[WRITE]] : $*Builtin.Int64
+// CHECK: br
+// CHECK: bb2:
+// CHECK: [[READ:%.*]] = begin_access [read] [static] undef : $*Builtin.Int64
+// CHECK: %{{.*}} = load [trivial] [[READ]] : $*Builtin.Int64
+// CHECK: end_access [[READ]] : $*Builtin.Int64
+// CHECK-LABEL: } // end sil function 'undefStack'
+sil hidden @undefStack : $@convention(thin) (Builtin.Int64) -> Builtin.Int64 {
+bb0(%0 : $Builtin.Int64):
+  unreachable
+
+bb1:
+  %23 = integer_literal $Builtin.Int64, 42
+  %25 = begin_access [modify] [unknown] undef : $*Builtin.Int64
+  store %23 to [trivial] %25 : $*Builtin.Int64
+  end_access %25 : $*Builtin.Int64
+  br bb2
+
+bb2:
+  %29 = begin_access [read] [unknown] undef : $*Builtin.Int64
+  %30 = load [trivial] %29 : $*Builtin.Int64
+  end_access %29 : $*Builtin.Int64
+  dealloc_stack undef : $*Builtin.Int64
+  return %30 : $Builtin.Int64
+}
+
+// Test static enforcement selection in the presence of mark_function_escape.
+// This really isn't really a special case, but depends on pass pipeline.
+//
+// CHECK-LABEL: sil hidden @markFuncEscape : $@convention(thin) () -> () {
+// CHECK: bb0:
+// CHECK:  [[BOX:%.*]] = alloc_box ${ var Builtin.Int64 }, var, name "x"
+// CHECK:  [[ADR:%.*]] = project_box [[BOX]] : ${ var Builtin.Int64 }, 0
+// CHECK:  mark_function_escape [[ADR]] : $*Builtin.Int64
+// CHECK:  [[READ:%.*]] = begin_access [read] [static] [[ADR]] : $*Builtin.Int64
+// CHECK:  %{{.*}} = load [trivial] [[READ]] : $*Builtin.Int64
+// CHECK:  end_access [[READ]] : $*Builtin.Int64
+// CHECK:  destroy_value [[BOX]] : ${ var Builtin.Int64 }
+// CHECK:  return %{{.*}} : $()
+// CHECK-LABEL:} // end sil function 'markFuncEscape'
+sil hidden @markFuncEscape : $@convention(thin) () -> () {
+  %2 = alloc_box ${ var Builtin.Int64 }, var, name "x"
+  %3 = project_box %2 : ${ var Builtin.Int64 }, 0
+  mark_function_escape %3 : $*Builtin.Int64
+  %39 = begin_access [read] [unknown] %3 : $*Builtin.Int64
+  %40 = load [trivial] %39 : $*Builtin.Int64
+  end_access %39 : $*Builtin.Int64
+  destroy_value %2 : ${ var Builtin.Int64 }
+  %98 = tuple ()
+  %99 = return %98 : $()
+}
+
+// Test static enforcement of copied boxes.
+// FIXME: Oops... We make this dynamic.
+//
+// CHECK-LABEL: sil hidden @copyBox : $@convention(thin) () -> () {
+// CHECK: bb0:
+// CHECK:  [[BOX:%.*]] = alloc_box ${ var Builtin.Int64 }, var, name "x"
+// CHECK:  [[ADR1:%.*]] = project_box [[BOX]] : ${ var Builtin.Int64 }, 0
+// CHECK:  [[CPY:%.*]] = copy_value [[BOX]] : ${ var Builtin.Int64 }
+// CHECK:  [[ADR2:%.*]] = project_box [[CPY]] : ${ var Builtin.Int64 }, 0
+// CHECK:  [[READ:%.*]] = begin_access [read] [dynamic] [[ADR2]] : $*Builtin.Int64
+// CHECK:  %{{.*}} = load [trivial] [[READ]] : $*Builtin.Int64
+// CHECK:  end_access [[READ]] : $*Builtin.Int64
+// CHECK:  [[READ:%.*]] = begin_access [read] [dynamic] [[ADR1]] : $*Builtin.Int64
+// CHECK:  %{{.*}} = load [trivial] [[READ]] : $*Builtin.Int64
+// CHECK:  end_access [[READ]] : $*Builtin.Int64
+// CHECK:  destroy_value [[CPY]] : ${ var Builtin.Int64 }
+// CHECK:  destroy_value [[BOX]] : ${ var Builtin.Int64 }
+// CHECK:  return %{{.*}} : $()
+// CHECK-LABEL: } // end sil function 'copyBox'
+sil hidden @copyBox : $@convention(thin) () -> () {
+  %2 = alloc_box ${ var Builtin.Int64 }, var, name "x"
+  %3 = project_box %2 : ${ var Builtin.Int64 }, 0
+  %16 = copy_value %2 : ${ var Builtin.Int64 }
+  %17 = project_box %16 : ${ var Builtin.Int64 }, 0
+  %18 = begin_access [read] [unknown] %17 : $*Builtin.Int64
+  %19 = load [trivial] %18 : $*Builtin.Int64
+  end_access %18 : $*Builtin.Int64
+  %39 = begin_access [read] [unknown] %3 : $*Builtin.Int64
+  %40 = load [trivial] %39 : $*Builtin.Int64
+  end_access %39 : $*Builtin.Int64
+  destroy_value %16 : ${ var Builtin.Int64 }
+  destroy_value %2 : ${ var Builtin.Int64 }
+  %98 = tuple ()
+  %99 = return %98 : $()
+}