Fix array bounds check optimization for ossa

In non-ossa, a dominance check is sufficient to check if a value is available
at a use point. In ossa this isn't sufficient since the lifetime of the value
may have ended. Ensure proper checks for ossa before hoisting an array value.

Author: meg-gupta

lib/SILOptimizer/Analysis/ArraySemantic.cpp

@@ -14,6 +14,7 @@
 #include "swift/Basic/Assertions.h"
 #include "swift/SIL/DebugUtils.h"
 #include "swift/SIL/InstructionUtils.h"
+#include "swift/SIL/PrunedLiveness.h"
 #include "swift/SIL/SILArgument.h"
 #include "swift/SIL/SILBuilder.h"
 #include "swift/SIL/SILFunction.h"
@@ -282,6 +283,26 @@ std::optional<int64_t> swift::ArraySemanticsCall::getConstantIndex() const {
   return Val.getSExtValue();
 }
 
+static bool isLiveAt(SILValue value, SILInstruction *newUser, DominanceInfo *DT) {
+  auto *func = value->getFunction();
+  if (!func->hasOwnership()) {
+    return DT->dominates(value->getParentBlock(), newUser->getParent());
+  }
+  SSAPrunedLiveness liveness(func);
+  liveness.initializeDef(value);
+  auto summary = liveness.computeSimple();
+  if (summary.addressUseKind != AddressUseKind::NonEscaping) {
+    return false;
+  }
+  if (summary.innerBorrowKind != InnerBorrowKind::Contained) {
+    return false;
+  }
+  if (!liveness.isWithinBoundary(newUser, /*deadEndBlocks=*/nullptr)) {
+    return false;
+  }
+  return true;
+}
+
 static bool canHoistArrayArgument(ApplyInst *SemanticsCall, SILValue Arr,
                                   SILInstruction *InsertBefore,
                                   DominanceInfo *DT) {
@@ -294,10 +315,11 @@ static bool canHoistArrayArgument(ApplyInst *SemanticsCall, SILValue Arr,
     return false;
 
   ValueBase *SelfVal = Arr;
-  auto *SelfBB = SelfVal->getParentBlock();
-  if (DT->dominates(SelfBB, InsertBefore->getParent()))
+  if (isLiveAt(SelfVal, InsertBefore, DT)) {
     return true;
+  }
 
+  // OSSAFIXME: Handle begin_borrow and load_borrow
   if (auto *Copy = dyn_cast<CopyValueInst>(SelfVal)) {
     // look through one level
     SelfVal = Copy->getOperand();

test/SILOptimizer/abcopts_ossa_guaranteed.sil

@@ -1458,3 +1458,103 @@ bb3:
   %r = tuple ()
   return %r : $()
 }
+
+// The bounds check isn't hoisted here since the array value for the isNativeTypeChecked is not available in the preheader  
+// Ensure we don't fail verification
+sil [ossa] @isNativeUnavailable1 : $@convention(thin) (Int32, @owned ArrayInt) -> Int32 {
+bb0(%0 : $Int32, %1 : @owned $ArrayInt):
+  %2 = integer_literal $Builtin.Int1, -1
+  %3 = struct $Bool (%2)
+  %4 = struct_extract %0, #Int32._value
+  %5 = integer_literal $Builtin.Int32, 0
+  %6 = builtin "cmp_eq_Int32"(%5, %4) : $Builtin.Int1
+  %7 = begin_borrow %1
+  %8 = copy_value %7
+  %9 = function_ref @arrayPropertyIsNative : $@convention(method) (@guaranteed ArrayInt) -> Bool
+  %10 = apply %9(%7) : $@convention(method) (@guaranteed ArrayInt) -> Bool
+  end_borrow %7
+  cond_br %6, bb2, bb1
+
+bb1:
+  br bb3(%5)
+
+bb2:
+  destroy_value %8
+  destroy_value %1
+  br bb6(%5)
+
+bb3(%17 : $Builtin.Int32):
+  %18 = struct $Int32 (%17)
+  %19 = function_ref @checkbounds : $@convention(method) (Int32, Bool, @guaranteed ArrayInt) -> _DependenceToken
+  %20 = apply %19(%18, %10, %8) : $@convention(method) (Int32, Bool, @guaranteed ArrayInt) -> _DependenceToken
+  %21 = integer_literal $Builtin.Int32, 1
+  %22 = integer_literal $Builtin.Int1, -1
+  %23 = builtin "sadd_with_overflow_Int32"(%17, %21, %22) : $(Builtin.Int32, Builtin.Int1)
+  %24 = tuple_extract %23, 0
+  %25 = tuple_extract %23, 1
+  cond_fail %25, ""
+  %27 = builtin "cmp_eq_Int32"(%24, %4) : $Builtin.Int1
+  cond_br %27, bb5, bb4
+
+bb4:
+  br bb3(%24)
+
+bb5:
+  destroy_value %8
+  destroy_value %1
+  br bb6(%24)
+
+bb6(%33 : $Builtin.Int32):
+  %34 = struct $Int32 (%33)
+  return %34
+}
+
+// The bounds check isn't hoisted here since the array value for the isNativeTypeChecked is not available in the preheader  
+// Ensure we don't fail verification
+sil [ossa] @isNativeUnavailable2 : $@convention(thin) (Int32, @owned ArrayInt) -> Int32 {
+bb0(%0 : $Int32, %1 : @owned $ArrayInt):
+  %2 = integer_literal $Builtin.Int1, -1
+  %3 = struct $Bool (%2)
+  %4 = struct_extract %0, #Int32._value
+  %5 = integer_literal $Builtin.Int32, 0
+  %6 = builtin "cmp_eq_Int32"(%5, %4) : $Builtin.Int1
+  %7 = copy_value %1
+  %8 = copy_value %7
+  %9 = function_ref @arrayPropertyIsNative : $@convention(method) (@guaranteed ArrayInt) -> Bool
+  %10 = apply %9(%7) : $@convention(method) (@guaranteed ArrayInt) -> Bool
+  destroy_value %7
+  cond_br %6, bb2, bb1
+
+bb1:
+  br bb3(%5)
+
+bb2:
+  destroy_value %8
+  destroy_value %1
+  br bb6(%5)
+
+bb3(%17 : $Builtin.Int32):
+  %18 = struct $Int32 (%17)
+  %19 = function_ref @checkbounds : $@convention(method) (Int32, Bool, @guaranteed ArrayInt) -> _DependenceToken
+  %20 = apply %19(%18, %10, %8) : $@convention(method) (Int32, Bool, @guaranteed ArrayInt) -> _DependenceToken
+  %21 = integer_literal $Builtin.Int32, 1
+  %22 = integer_literal $Builtin.Int1, -1
+  %23 = builtin "sadd_with_overflow_Int32"(%17, %21, %22) : $(Builtin.Int32, Builtin.Int1)
+  %24 = tuple_extract %23, 0
+  %25 = tuple_extract %23, 1
+  cond_fail %25, ""
+  %27 = builtin "cmp_eq_Int32"(%24, %4) : $Builtin.Int1
+  cond_br %27, bb5, bb4
+
+bb4:
+  br bb3(%24)
+
+bb5:
+  destroy_value %8
+  destroy_value %1
+  br bb6(%24)
+
+bb6(%33 : $Builtin.Int32):
+  %34 = struct $Int32 (%33)
+  return %34
+}