Remove metric fields

[devmotion]

It seems the metric fields are not needed, it is sufficient to define the metric(::Kernel) trait.

[theogf]

Doesn't it create unnecessary allocations ?
Maybe an alternative would be to create const objects of each metric in the package.

const m_sqeuclidean = SqEuclidean()
metric(::SqExponential) = m_sqeuclidean

[devmotion]

I just assumed the compiler is smart enough (and the implementation in Distances.jl would be different otherwise) 😄 To be sure that there are no allocations, I used the following benchmark script:

using Distances
using BenchmarkTools

struct A
    metric::SqEuclidean
end

A() = A(SqEuclidean())

metric(::A) = SqEuclidean()

const SQEUCLIDEAN = SqEuclidean()
metric_const(::A) = SQEUCLIDEAN

evaluate_field(a::A, x, y) = evaluate(a.metric, x, y)
evaluate_function(a::A, x, y) = evaluate(metric(a), x, y)
evaluate_const(a::A, x, y) = evaluate(metric_const(a), x, y)

function test(N::Int)
    a = A()
    x = rand(N)
    y = rand(N)

    @btime evaluate_field($a, $x, $y)
    @btime evaluate_function($a, $x, $y)
    @btime evaluate_const($a, $x, $y)

    nothing
end

I got the following results:

julia> test(10_000)
  1.778 μs (0 allocations: 0 bytes)
  1.783 μs (0 allocations: 0 bytes)
  1.785 μs (0 allocations: 0 bytes)

julia> test(100_000)
  23.819 μs (0 allocations: 0 bytes)
  23.808 μs (0 allocations: 0 bytes)
  23.824 μs (0 allocations: 0 bytes)

So the approach shouldn't introduce any allocations.

[theogf]

Thanks a lot for making all the benchmarks and your contribution!