implement dbg for if expressions

lib/elixir/lib/macro.ex

@@ -2642,6 +2642,15 @@ defmodule Macro do
     end
   end
 
+  defp dbg_ast_to_debuggable({:if, _meta, [condition_ast, _clauses]} = ast) do
+    quote do
+      condition_result = unquote(condition_ast)
+      result = unquote(ast)
+
+      {:if, unquote(escape(ast)), unquote(escape(condition_ast)), condition_result, result}
+    end
+  end
+
   # Any other AST.
   defp dbg_ast_to_debuggable(ast) do
     quote do: {:value, unquote(escape(ast)), unquote(ast)}
@@ -2755,6 +2764,23 @@ defmodule Macro do
     {formatted, value}
   end
 
+  defp dbg_format_ast_to_debug(
+         {:if, ast, condition_ast, condition_result, result},
+         options
+       ) do
+    formatted = [
+      dbg_maybe_underline("If condition", options),
+      ":\n",
+      dbg_format_ast_with_value(condition_ast, condition_result, options),
+      ?\n,
+      dbg_maybe_underline("If expression", options),
+      " (#{if result, do: "do", else: "else"} clause executed):\n",
+      dbg_format_ast_with_value(ast, result, options)
+    ]
+
+    {formatted, result}
+  end
+
   defp dbg_format_ast_to_debug({:value, code_ast, value}, options) do
     {dbg_format_ast_with_value(code_ast, value, options), value}
   end

lib/elixir/test/elixir/macro_test.exs

@@ -536,6 +536,62 @@ defmodule MacroTest do
              """
     end
 
+    test "if statement" do
+      x = true
+      map = %{a: 5, b: 1}
+
+      {result, formatted} =
+        dbg_format(
+          if true and x do
+            map[:a] * 2
+          else
+            map[:b]
+          end
+        )
+
+      assert result == 10
+
+      assert formatted =~ "macro_test.exs"
+
+      assert formatted =~ """
+             If condition:
+             true and x #=> true
+
+             If expression (do clause executed):
+             if true and x do
+               map[:a] * 2
+             else
+               map[:b]
+             end #=> 10
+             """
+    end
+
+    test "if statement without else" do
+      x = true
+      map = %{a: 5, b: 1}
+
+      {result, formatted} =
+        dbg_format(
+          if false and x do
+            map[:a] * 2
+          end
+        )
+
+      assert result == nil
+
+      assert formatted =~ "macro_test.exs"
+
+      assert formatted =~ """
+             If condition:
+             false and x #=> false
+
+             If expression (else clause executed):
+             if false and x do
+               map[:a] * 2
+             end #=> nil
+             """
+    end
+
     test "with \"syntax_colors: []\" it doesn't print any color sequences" do
       {_result, formatted} = dbg_format("hello")
       refute formatted =~ "\e["