Add cursor movement to IO.ANSI

lib/elixir/lib/io/ansi.ex

@@ -170,6 +170,32 @@ defmodule IO.ANSI do
   @doc "Sends cursor home."
   defsequence(:home, "", "H")
 
+  @doc """
+  Sends cursor to the absolute position specified by `line` and `column`.
+
+  Line `0` and column `0` would mean the top left corner.
+  """
+  @spec cursor(integer, integer) :: String.t()
+  def cursor(line, column)
+      when is_integer(line) and line >= 0 and is_integer(column) and column >= 0,
+      do: "\e[#{line};#{column}H"
+
+  @doc "Sends cursor `lines` up."
+  @spec cursor_up(integer) :: String.t()
+  def cursor_up(lines \\ 1) when is_integer(lines) and lines > 0, do: "\e[#{lines}A"
+
+  @doc "Sends cursor `lines` down."
+  @spec cursor_down(integer) :: String.t()
+  def cursor_down(lines \\ 1) when is_integer(lines) and lines > 0, do: "\e[#{lines}B"
+
+  @doc "Sends cursor `columns` to the left."
+  @spec cursor_left(integer) :: String.t()
+  def cursor_left(columns \\ 1) when is_integer(columns) and columns > 0, do: "\e[#{columns}C"
+
+  @doc "Sends cursor `columns` to the right."
+  @spec cursor_right(integer) :: String.t()
+  def cursor_right(columns \\ 1) when is_integer(columns) and columns > 0, do: "\e[#{columns}D"
+
   @doc "Clears screen."
   defsequence(:clear, "2", "J")
 

lib/elixir/test/elixir/io/ansi_test.exs

@@ -155,4 +155,53 @@ defmodule IO.ANSITest do
       IO.ANSI.color_background(5, -1, 1)
     end
   end
+
+  test "cursor/2" do
+    assert IO.ANSI.cursor(0, 0) == "\e[0;0H"
+    assert IO.ANSI.cursor(11, 12) == "\e[11;12H"
+
+    assert_raise FunctionClauseError, fn ->
+      IO.ANSI.cursor(-1, 5)
+    end
+
+    assert_raise FunctionClauseError, fn ->
+      IO.ANSI.cursor(5, -1)
+    end
+  end
+
+  test "cursor_up/1" do
+    assert IO.ANSI.cursor_up() == "\e[1A"
+    assert IO.ANSI.cursor_up(12) == "\e[12A"
+
+    assert_raise FunctionClauseError, fn ->
+      IO.ANSI.cursor_up(-1)
+    end
+  end
+
+  test "cursor_down/1" do
+    assert IO.ANSI.cursor_down() == "\e[1B"
+    assert IO.ANSI.cursor_down(2) == "\e[2B"
+
+    assert_raise FunctionClauseError, fn ->
+      IO.ANSI.cursor_down(-1)
+    end
+  end
+
+  test "cursor_left/1" do
+    assert IO.ANSI.cursor_left() == "\e[1C"
+    assert IO.ANSI.cursor_left(3) == "\e[3C"
+
+    assert_raise FunctionClauseError, fn ->
+      IO.ANSI.cursor_left(-1)
+    end
+  end
+
+  test "cursor_right/0" do
+    assert IO.ANSI.cursor_right() == "\e[1D"
+    assert IO.ANSI.cursor_right(4) == "\e[4D"
+
+    assert_raise FunctionClauseError, fn ->
+      IO.ANSI.cursor_right(-1)
+    end
+  end
 end