Added baseline utility

CHANGELOG.md

@@ -12,6 +12,7 @@ and this project adheres to [Semantic Versioning](https://semver.org/spec/v2.0.0
 - Pre-release support for IPM v0.9.0+
 - Items mapped from database other than namespace's default routine database are now ignored by default when exporting or adding files
 - New setting to configure whether mapped items should be should be treated as read-only
+- Command-line utility to do a baseline export of items in a namespace
 
 ## [2.3.1] - 2024-04-30
 

cls/SourceControl/Git/API.cls

@@ -56,5 +56,12 @@ ClassMethod Unlock()
     quit ##class(SourceControl.Git.Utils).Locked(0)
 }
 
+/// Run in terminal to baseline a namespace by adding all items to source control.
+/// - pCommitMessage: if defined, all changes in namespace context will be committed.
+/// - pPushToRemote: if defined, will run a git push to the specified remote
+ClassMethod BaselineExport(pCommitMessage = "", pPushToRemote = "") As %Status
+{
+    quit ##class(SourceControl.Git.Utils).BaselineExport(pCommitMessage, pPushToRemote)
 }
 
+}

cls/SourceControl/Git/Utils.cls

@@ -513,6 +513,7 @@ ClassMethod AddToServerSideSourceControl(InternalName As %String) As %Status
 
 ClassMethod AddToSourceControl(InternalName As %String) As %Status
 {
+    do ##class(SourceControl.Git.PackageManagerContext).ForInternalName(InternalName)
     set settings = ##class(SourceControl.Git.Settings).%New()
     #dim i as %Integer
     #dim ec as %Status = $$$OK
@@ -2062,5 +2063,47 @@ ClassMethod ResetSourceControlClass()
     do ##class(%Studio.SourceControl.Interface).SourceControlClassSet("")
 }
 
+ClassMethod BaselineExport(pCommitMessage = "", pPushToRemote = "") As %Status
+{
+    set sc = $$$OK
+    try {
+        write !, "Exporting items..."
+        set rs = ##class(%Library.RoutineMgr).StudioOpenDialogFunc(
+            "*.mac,*.int,*.inc,*.cls,*.csp" // Spec
+            , , ,0  // SystemFiles
+            ,1      // Flat
+            ,0      // NotStudio
+            ,0      // ShowGenerated
+            , , ,0  // Mapped
+            )
+        throw:rs.%SQLCODE<0 ##class(%Exception.SQL).CreateFromSQLCODE(rs.%SQLCODE,rs.%Message)
+        while rs.%Next(.sc) {
+            $$$ThrowOnError(sc)
+            set internalName = rs.Name
+            // exclude items in a non-default IPM package
+            set context = ##class(SourceControl.Git.PackageManagerContext).ForInternalName(internalName)
+            continue:($isobject(context.Package) && 'context.IsInDefaultPackage)
+            $$$ThrowOnError(..AddToSourceControl(internalName))
+        }
+        if pCommitMessage '= "" {
+            // switch to default context
+            do ##class(SourceControl.Git.PackageManagerContext).ForInternalName("")
+            do ..RunGitWithArgs(.errStream, .outStream, "add", "--all")
+            do ..PrintStreams(errStream, outStream)
+            set username = ..GitUserName()
+            set email = ..GitUserEmail()
+            set author = username_" <"_email_">"
+            do ..RunGitWithArgs(.errStream, .outStream, "commit", "--author", author, "-m", pCommitMessage)
+            do ..PrintStreams(errStream, outStream)
+            $$$ThrowOnError(##class(SourceControl.Git.Change).RefreshUncommitted(,,,1))
+            if (pPushToRemote '= "") {
+                $$$ThrowOnError(..Push(pPushToRemote))
+            }
+        }
+    } catch err {
+        set sc = err.AsStatus()
+    }
+    return sc
 }
 
+}

test/UnitTest/SourceControl/Git/BaselineExport.cls

@@ -0,0 +1,61 @@
+Class UnitTest.SourceControl.Git.BaselineExport Extends %UnitTest.TestCase
+{
+
+Method TestBaselineExport()
+{
+    // create a mac routine
+	if '##class(%Routine).Exists("test.mac") {
+		set r = ##class(%Routine).%New("test.mac")
+		do r.WriteLine(" write 22,!")
+		do r.Save()
+		do r.Compile()
+	}
+    // create an inc routine
+	if '##class(%Routine).Exists("test.inc") {
+		set r = ##class(%Routine).%New("test.inc")
+		do r.WriteLine(" ; test include routine")
+		do r.Save()
+		do r.Compile()
+	}
+    // create a class
+    if '##class(%Dictionary.ClassDefinition).%OpenId("TestPkg.Class") {
+        set class = ##class(%Dictionary.ClassDefinition).%New()
+        set class.Name = "TestPkg.Class"
+        $$$ThrowOnError(class.%Save())
+        do $system.OBJ.Compile("TestPkg.Class")
+    }
+    do $$$AssertNotTrue(##class(SourceControl.Git.Utils).IsInSourceControl("test.mac"))
+    do $$$AssertNotTrue(##class(SourceControl.Git.Utils).IsInSourceControl("test.inc"))
+    do $$$AssertNotTrue(##class(SourceControl.Git.Utils).IsInSourceControl("TestPkg.Class.cls"))
+    do $$$AssertStatusOK(##class(SourceControl.Git.API).BaselineExport())
+    do $$$AssertTrue(##class(SourceControl.Git.Utils).IsInSourceControl("test.mac"))
+    do $$$AssertTrue(##class(SourceControl.Git.Utils).IsInSourceControl("test.inc"))
+    do $$$AssertTrue(##class(SourceControl.Git.Utils).IsInSourceControl("TestPkg.Class.cls"))
+}
+
+Property InitialExtension As %String [ InitialExpression = {##class(%Studio.SourceControl.Interface).SourceControlClassGet()} ];
+
+Property SourceControlGlobal [ MultiDimensional ];
+
+Method %OnNew(initvalue) As %Status
+{
+	Merge ..SourceControlGlobal = ^SYS("SourceControl")
+	Kill ^SYS("SourceControl")
+	Set settings = ##class(SourceControl.Git.Settings).%New()
+	Set settings.namespaceTemp = ##class(%Library.File).TempFilename()_"dir"
+	Set settings.Mappings("MAC","*")="rtn/"
+	Set settings.Mappings("CLS","*")="cls/"
+	Do settings.%Save()
+	Do ##class(%Studio.SourceControl.Interface).SourceControlClassSet("SourceControl.Git.Extension")
+	Quit ##super(initvalue)
+}
+
+Method %OnClose() As %Status [ Private, ServerOnly = 1 ]
+{
+	Do ##class(%Studio.SourceControl.Interface).SourceControlClassSet(..InitialExtension)
+	Kill ^SYS("SourceControl")
+	Merge ^SYS("SourceControl") = ..SourceControlGlobal
+	Quit $$$OK
+}
+
+}