[cast-opt] Create an ownership version of bridged_cast_folding.sil an…

lib/SILOptimizer/Utils/CastOptimizer.cpp

@@ -514,13 +514,18 @@ static SILValue computeFinalCastedValue(SILBuilderWithScope &builder,
     auto *failureBB = dynamicCast.getFailureBlock();
     {
       SILBuilderWithScope innerBuilder(&*failureBB->begin(), builder);
-      innerBuilder.emitDestroyValueOperation(loc, newAI);
+      auto valueToDestroy = ([&]() -> SILValue {
+        if (!innerBuilder.hasOwnership())
+          return newAI;
+        return failureBB->createPhiArgument(newAI->getType(),
+                                            ValueOwnershipKind::Owned);
+      }());
+      innerBuilder.emitDestroyValueOperation(loc, valueToDestroy);
     }
 
     auto *condBrSuccessBB =
         newAI->getFunction()->createBasicBlockAfter(newAI->getParent());
-    condBrSuccessBB->createPhiArgument(destTy, ValueOwnershipKind::Owned,
-                                       nullptr);
+    condBrSuccessBB->createPhiArgument(destTy, ValueOwnershipKind::Owned);
     builder.createCheckedCastBranch(loc, /* isExact*/ false, newAI, destTy,
                                     condBrSuccessBB, failureBB);
     builder.setInsertionPoint(condBrSuccessBB, condBrSuccessBB->begin());
@@ -709,10 +714,13 @@ CastOptimizer::optimizeBridgedSwiftToObjCCast(SILDynamicCastInst dynamicCast) {
   if (!Dest)
     return NewAI;
 
-  // If it is addr cast then store the result.
+  // If it is addr cast then store the result into the dest.
+  //
+  // NOTE: We assume that dest was uninitialized when passed to us.
   SILValue castedValue = computeFinalCastedValue(Builder, dynamicCast, NewAI);
-  SILInstruction *NewI = Builder.createStore(
-      Loc, castedValue, Dest, StoreOwnershipQualifier::Unqualified);
+  auto qual = Builder.hasOwnership() ? StoreOwnershipQualifier::Init
+                                     : StoreOwnershipQualifier::Unqualified;
+  SILInstruction *NewI = Builder.createStore(Loc, castedValue, Dest, qual);
   if (isConditional && NewI->getParent() != NewAI->getParent()) {
     Builder.createBranch(Loc, SuccessBB);
   }

test/SILOptimizer/bridged_casts_folding.sil

@@ -41,7 +41,7 @@ bb1:
 
 bb2:
   br bb3(%1 : $NSObjectSubclass)
-  
+
 bb3(%8 : @owned $NSObjectSubclass):
   dealloc_stack %2 : $*NSObjectSubclass
   return %8 : $NSObjectSubclass
@@ -66,7 +66,7 @@ bb1:
 bb2:
   destroy_addr %0 : $*AnyHashable
   br bb3(%1 : $NSObjectSubclass)
-  
+
 bb3(%8 : @owned $NSObjectSubclass):
   dealloc_stack %2 : $*NSObjectSubclass
   return %8 : $NSObjectSubclass
@@ -94,7 +94,7 @@ bb1:
 
 bb2:
   br bb3(%1 : $NSObjectSubclass)
-  
+
 bb3(%8 : @owned $NSObjectSubclass):
   dealloc_stack %2 : $*NSObjectSubclass
   return %8 : $NSObjectSubclass

test/SILOptimizer/bridged_casts_folding_ownership.sil

@@ -0,0 +1,103 @@
+// RUN: %target-swift-frontend -enable-ownership-stripping-after-serialization -module-name bridged_casts_folding -O -emit-sil %s | %FileCheck %s
+
+// REQUIRES: objc_interop
+
+sil_stage raw
+
+import Swift
+import Foundation
+
+class NSObjectSubclass : NSObject {}
+sil_vtable NSObjectSubclass {}
+
+// CHECK-LABEL: sil @anyhashable_cast_unconditional :
+// CHECK:         [[BRIDGED:%.*]] = apply {{.*}}(%0)
+// CHECK-NEXT:    destroy_addr %0
+// CHECK-NEXT:    [[CAST:%.*]] = unconditional_checked_cast [[BRIDGED]] : $NSObject to $NSObjectSubclass
+// CHECK-NEXT:    return [[CAST]]
+// CHECK: } // end sil function 'anyhashable_cast_unconditional'
+sil [ossa] @anyhashable_cast_unconditional : $@convention(thin) (@in AnyHashable) -> @owned NSObjectSubclass {
+entry(%0 : $*AnyHashable):
+  %1 = alloc_stack $NSObjectSubclass
+  unconditional_checked_cast_addr AnyHashable in %0 : $*AnyHashable
+                               to NSObjectSubclass in %1 : $*NSObjectSubclass
+  %3 = load [take] %1 : $*NSObjectSubclass
+  dealloc_stack %1 : $*NSObjectSubclass
+  return %3 : $NSObjectSubclass
+}
+
+// CHECK-LABEL: sil @anyhashable_cast_take_always
+// CHECK:         [[BRIDGED:%.*]] = apply {{.*}}(%0)
+// CHECK-NEXT:    destroy_addr %0
+// CHECK-NEXT:    checked_cast_br [[BRIDGED]] : $NSObject to $NSObjectSubclass, [[YES:bb[0-9]+]], [[NO:bb[0-9]+]]
+sil [ossa] @anyhashable_cast_take_always : $@convention(thin) (@in AnyHashable, @owned NSObjectSubclass) -> @owned NSObjectSubclass {
+entry(%0 : $*AnyHashable, %1 : @owned $NSObjectSubclass):
+  %2 = alloc_stack $NSObjectSubclass
+  checked_cast_addr_br take_always AnyHashable in %0 : $*AnyHashable
+                 to NSObjectSubclass in %2 : $*NSObjectSubclass, bb1, bb2
+
+bb1:
+  %4 = load [take] %2 : $*NSObjectSubclass
+  destroy_value %1 : $NSObjectSubclass
+  br bb3(%4 : $NSObjectSubclass)
+
+bb2:
+  br bb3(%1 : $NSObjectSubclass)
+
+bb3(%8 : @owned $NSObjectSubclass):
+  dealloc_stack %2 : $*NSObjectSubclass
+  return %8 : $NSObjectSubclass
+}
+
+// CHECK-LABEL: sil @anyhashable_cast_take_on_success
+// CHECK:         [[BRIDGED:%.*]] = apply {{.*}}(%0)
+// CHECK-NEXT:    checked_cast_br [[BRIDGED]] : $NSObject to $NSObjectSubclass, [[YES:bb[0-9]+]], [[NO:bb[0-9]+]]
+// CHECK:       [[YES]]{{.*}}:
+// CHECK-NEXT:    destroy_addr %0
+sil [ossa] @anyhashable_cast_take_on_success : $@convention(thin) (@in AnyHashable, @owned NSObjectSubclass) -> @owned NSObjectSubclass {
+entry(%0 : $*AnyHashable, %1 : @owned $NSObjectSubclass):
+  %2 = alloc_stack $NSObjectSubclass
+  checked_cast_addr_br take_on_success AnyHashable in %0 : $*AnyHashable
+                 to NSObjectSubclass in %2 : $*NSObjectSubclass, bb1, bb2
+
+bb1:
+  %4 = load [take] %2 : $*NSObjectSubclass
+  destroy_value %1 : $NSObjectSubclass
+  br bb3(%4 : $NSObjectSubclass)
+
+bb2:
+  destroy_addr %0 : $*AnyHashable
+  br bb3(%1 : $NSObjectSubclass)
+
+bb3(%8 : @owned $NSObjectSubclass):
+  dealloc_stack %2 : $*NSObjectSubclass
+  return %8 : $NSObjectSubclass
+}
+
+// CHECK-LABEL: sil @anyhashable_cast_copy_on_success
+// CHECK-NOT:         copy_addr
+// CHECK:    [[BRIDGED:%.*]] = apply {{.*}}(%0)
+// CHECK-NOT:    destroy_addr
+// CHECK-NEXT:    checked_cast_br [[BRIDGED]] : $NSObject to $NSObjectSubclass, [[YES:bb[0-9]+]], [[NO:bb[0-9]+]]
+// CHECK:       [[YES]]{{.*}}:
+// CHECK-NOT:    dealloc_stack
+// CHECK:       [[NO]]{{.*}}:
+// CHECK-NOT:    dealloc_stack
+sil [ossa] @anyhashable_cast_copy_on_success : $@convention(thin) (@in_guaranteed AnyHashable, @owned NSObjectSubclass) -> @owned NSObjectSubclass {
+entry(%0 : $*AnyHashable, %1 : @owned $NSObjectSubclass):
+  %2 = alloc_stack $NSObjectSubclass
+  checked_cast_addr_br copy_on_success AnyHashable in %0 : $*AnyHashable
+                 to NSObjectSubclass in %2 : $*NSObjectSubclass, bb1, bb2
+
+bb1:
+  %4 = load [take] %2 : $*NSObjectSubclass
+  destroy_value %1 : $NSObjectSubclass
+  br bb3(%4 : $NSObjectSubclass)
+
+bb2:
+  br bb3(%1 : $NSObjectSubclass)
+
+bb3(%8 : @owned $NSObjectSubclass):
+  dealloc_stack %2 : $*NSObjectSubclass
+  return %8 : $NSObjectSubclass
+}